
The story title is "I, Thief".
The story author is "Drew Cook".
The story headline is "A Cave Game™".
[The story headline is "Episode Two in the Entropist Adventure Series"]

Release number is 0.
Include Basic Screen Effects by Emily Short.
Include Locksmith by Emily Short.
Include Hybrid Choices by AW Freyr.
Include Menus by Wade Clarke.
Include Basic Help Menu by Wade Clarke.

PROD is a truth state that varies.
PROD is usually true.
Use American dialect.
Use the serial comma.	

Volume 1 (Preliminary Stuff)

Book 1 (some stuff for test)

Chapter 1 - not for release

Section 1 (Debug Switch)

PROD is false.

Section 2 (test only commands and responses)

After reading a command:
	if the player's command matches the regular expression "^\p|^<*#+='>":
		say "(Noted.)";
		reject the player's command;
		
[I learned this from Brian Rushton]

Adescing is an action applying to nothing.
Understand	"AD" as adescing.

Carry out ADESCing:
	repeat with current running through things:
		if current is not nothing:
			say "[current]: [description of current][paragraph break]"
			
[modified from Inform Manual]

this is the empty description rule:
	repeat with item running through things:
		if description of the item is "":
			say "[item] has no description."
			
EDing is an action applying to nothing.
Understand "ED" as EDing.

Carry out EDing:
	follow the empty description rule.
	
section 3 - test commands

aphosing is an action out of world applying to one value.
understand "ap [aphosis]" as aphosing.

aplisting is an action out of world applying to nothing.
understand "ap" as aplisting.

carry out aplisting:
	repeat through the table of aphoses:
		say "[aphosis entry]: [diagstring entry][lb]".

carry out aphosing:
	let n be the aphosis understood;
	now the aphosis of the player is n;
	try assaying the player.
	
Book 2 (Customized Responses)

Chapter 1 (action responses)

Chapter 2 (parser errors)

the parser error internal rule response (E) is "[if the player is in primordial darkness]You are not even sure if [it]you[rt] are here in this darkness.[otherwise]You do not sense that here."

Book 3 (data)

Chapter 1 (various is-ses)

Section 1 - kinds

A valuable is a kind of thing.

a thing can be aphotic.
a thing is usually not aphotic.

a thing can be assayed.
a thing is usually not assayed.

a thing can be deluminable.
a thing is usually not deluminable.

a thing can be delumined.
a thing is usually not delumined.

report delumining something when the noun is not delumined:
	now the noun is delumined;
	
a thing can be droppable or precious.
a thing is usually droppable.

instead of dropping something droppable:
	say "You examine the [noun] closely.

[ro]

MANY SAY THAT EVERY THING AND PLACE MUST HAVE UTILITY, BUT NO ONE KNOWS THE MIND OF THE DEMIURGE.

[rc]

[if the player carries the sack]Reconsidering, you place the [noun] in the sack[dot][otherwise]You decide to keep the [noun][dot][end if] It must have some hidden purpose.

[oc]

IF THE PLAYER CARRIES THE SACK:
[lb][t2][fls]IF THE NOUN IS NOT ENCLOSED BY THE SACK:
[lb][t2][t2][fls]TRY INSERTING THE NOUN INTO THE SACK.

[cc][lb]";
	if the player carries the sack:
		if the noun is not enclosed by the sack:
			try inserting the noun into the sack.
			
a door can be busted. a door is usually not busted.

Instead of doing anything other than gathering, delumining, assaying, or examining when the noun is  aphotic or the second noun is aphotic:
	say "Without your intervention, darkness is mere absence and lack.".
	
instead of delumining something aphotic:
	say "You cannot make darkness from darkness.".
	
a thing can be wet.
a thing is usually not wet.

after examining something wet:
	say "It's damp. A damp thing is damp until it isn't."
	
after delumining something when the player is damp and the noun is not the big light:
	say "Dampness follows your eyes and hand, falling over the [noun] with a splat.";
	now the noun is wet;
	now the player is tinert;

Aphosis is a kind of value.
The plural of aphosis is aphoses.
The aphoses are defined by the Table of Aphoses.

disposition is a kind of value. The dispositions are intact and banished.
a thing has a disposition.

adversarial stonework is a kind of thing. [the guardians and parts of the guardians]
the plural of adversarial stonework is adversarial stoneworks.

A thing can be examined or unexamined.
A thing is usually unexamined.

After examining something:
	now the noun is examined.
	

to decide if the paradox is already fulfilled:
	let CA be the current action;
	if there is an anomaly of the CA in the table of causal anomalies:
		choose row with an anomaly of CA in the table of causal anomalies;
		if turns passed entry is greater than zero:
			decide yes;
		otherwise:
			decide no;
	otherwise:
		decide no.

Section 2 (conversation)



Section 3 (photons and aphotics)



A thing can be a photon.
A thing is usually not a photon.

Chapter 2 (tables)

Section 1 - Aphoses

Table of Aphoses
aphosis	diagstring	pname
tinert	"You bear no darkness beyond your own."	"Inert"
exploding	"You bear the power of *CRASHING DARKNESS*: the power of force, of striking."	"*CRASHING DARKNESS*"
damp	"You bear the power of *SEEPING DARKNESS*: the power of water, of covering."	"*SEEPING DARKNESS*"
gooey	"You bear the power of *SUFFOCATING DARKNESS*: the power of blotting, of choking."	"*SUFFOCATING DARKNESS*"

to say magic at hand:
	let the player's condition be the aphosis of the player;
	say pname corresponding to an aphosis of the player's condition in the table of aphoses.

[say diagstring corresponding to a siphontype of the siphontype of the player in the table of diagnoses]

Section 2 - scoring

table of demerits
action performed	description	point value	turn stamp
thief delumining the pwd	"Destroying the plain, wooden door"	10	-1
thief getting past the guardians	"Getting past the Guardians of Zork"	10	-1
thief taking the sack	"Reclaiming a lost posession"	10	-1
thief returning to darkness	"Turning Off the Big Light"	10	-1
thief attaining the end	"Returning to the Scene of the Crime"	10	-1

table of rankings
score	rank
300	"Time Traveller"
310	"Messmaker"
330	"Sculptor"
340	"Imperialist"
350	"Emperor's Second Spymaster"

Section 3 - anomalies

table of causal anomalies
anomaly	turns passed	description	failure response
thief collapsing the dressed stone corridor	-1	"Your decision to bury yourself under a newly collapsed corridor was reversed by the Demiurge."	"[ro][pb]NO, [lct]. NOTHING CAN KEEP YOU FROM YOUR FATE.[pb][rc][lb]"
thief being crushed by statuary	-1	"You attempted to walk past the guardian statuary[em]or parts thereof."	"[ro][pb]YOU WILL NOT ESCAPE THIS STORY SO EASILY.[pb][rc][lb]"
thief kicking the can	-1	"You temporarily liquefied your forearm."	"[ro][pb]YOU CANNOT REACH YOUR DESTINY WITHOUT YOUR LIMBS, AND I WILL SEE YOU REACH IT.[pb][rc][lb]"
thief raising a ruckus	-1	"You ignored a rather dangerous-sounding rumble in an earthquake-prone passageway."	"[ro][pb]WHY DO YOU RESIST ME? ACCEPT YOUR FATE.[lct].[pb][rc][lb]"
thief being wet	-1	"A rockfall nearly crushed you in a damp passageway."	"[ro][pb]THAT DIDN'T WORK THE FIRST TIME. DID YOU THINK I WOULD FORGET?[pb][rc][lb]"
thief empowering the snake	-1	"You fed a serpent devouring reality."	"[ro][pb]NO, [CAP], YOU AREN'T YET A MATCH FOR THE SERPENT.[pb][rc][lb]"
thief teasing the shadow dorn	-1	"You lingered too long in the monstrous west."	"[ro][pb][if the location is not creepy crawl]YOU MUST NOT LINGER IN THE MONSTROUS WEST[otherwise] YOUR EXPERIMENTS IN THE MONSTROUS WEST ARE OVER[END IF]. I HAVE OTHER PLANS FOR YOU.[pb][rc][pb]"
thief being stumped by the puzzle	-1	"You wandered into that famous deathtrap, the Royal Puzzle."	"[ro][pb]I CAN'T BELIEVE YOU WENT IN THERE ONCE. WHY WOULD YOU TRY A SECOND TIME?[pb][rc][lb]"
thief stepping into the light	-1	"You lingered too long in the presence of the Big Light."	"[ro][pb]WHY RUSH, [CAP]? DO YOU WORRY A COLD SUNRISE WILL NEVER COME?[pb][rc][lb][vls]"
thief having a sunburn	-1	"Don't tease the Big Light, [lct]"	"[ro][pb][uct], EVEN THE BIG LIGHT MUST BEND TO MY WILL. STOP FIGHTING.[pb][rc][lb][vls]"
thief being buried alive	-1	"#1 in a series on time travel blunders! Collect them all!"	"[ro][pb]DON'T OVERDO IT, [lct].[pb][rc][lb][vls]"
thief missing your chance	-1	"#2 in a series on time travel blunders! Collect them all!"	"[ro][pb]NO, I WILL NOT PERMIT IT. WHAT RIGHT DOES HE/YOU HAVE TO KNOW?[pb][rc][lb][vls]"
thief meeting royalty	-1	"#3 in a series on time travel blunders! Collect them all!"	"[ro][pb]DID YOU THINK YOUR IMPERIAL PAST COULD PROTECT YOU? WHEN HAS POWER EVER BEEN EXCHANGED MUTUALLY?[pb][rc][lb][vls]"
thief getting zapped	-1	"#4 in a series on time travel blunders! Collect them all!"	"[ro][pb]NO, [lct]. YOU CANNOT CHANGE YOUR PATH. YOUR EVERY STEP HAS BEEN ORDAINED.[pb][rc][lb][vls]"
thief lighting up the past	-1	"#5 in a series on time travel blunders! Collect them all!"	"[ro][pb]NO. YOUR DAYS IN THE SUN ARE OVER.[pb][rc][lb][vls]"
thief arriving late to the party	-1	"#6 in series on time travel blunders! Collect them all!"	"[ro][pb]948 IS TOO LATE. YOUR FATE LIES IN 947.[pb][rc][lb][vls]"
thief being illuminated	-1	"You walked into direct sunlight."	"[ro][pb]IN SPITE OF THE FUTILITY OF REBELLION, YOU CONSIDER TO RESIST. ACCEPT YOUR DESTINY, [CAP].[pb][rc][lb][fls]"




Section 4 - historical contexts

[table of historical contexts
milestone	timing	flavor
theft at the royal museum	776	""
dedication of the roual museum	777	""
Lord Dimwit Flathead Dies	789	""
Fall of the Empire	883	""
Rise of the Second Dungeon Master	948	""
End of the Age of Magic	968	""]

Chapter 3 (substitutions)

Section 1 (special characters and such)

[action to distinguish emdash settings for mono and variable fonts]

monoing is an action applying to nothing.
understand "mono" and "monospace" as monoing.

carry out monoing:
	if mspace is true:
		now mspace is false;
		stop the action;
	if mspace is false:
		now mspace is true;
		stop the action.

mspace is a truth state that varies.
mspace is usually false.

To say EM:
	say "[if mspace is false][unicode 8212][otherwise] - [end if]"[EM].
	
To say em:
say "[if mspace is false][unicode 8212][otherwise] - [end if]"[EM].
	
[I've been told that substituting punctuation is not the "correct" way to deal with errant line breaks. But the right way requires more typing, which I hardly consider "correct."]

To say DOT:
	say "[unicode 46]"[DOT].
	
To say dot:
	say "[unicode 46]"[DOT].	
	
[DOT and some others replace punctuation that otherwise would lead to unwanted line breaks]
	
To say tab:
	say "[fixed letter spacing]   [variable letter spacing]"[TAB].
	
To say t2:
	say "[fixed letter spacing]     [variable letter spacing]"[t2].
	
To say F2:
	say "[line break][fixed letter spacing]     "[F2].
	
To say T2:
	say "[fixed letter spacing]     [variable letter spacing]"[t2].
	
To say blt:
	say "[tab]~ [variable letter spacing]"[blt]
	
To say cstblt:
	say "[fls] ~  [vls]"
	
To say cstblt1:
	say "[fls]  ~  [vls]"
	
To say blt2:
	say "[fls]   [vls] [fls]~[vls] "[blt2]
	
to say bk:
	say "[bracket]"
	
to say cb:
	say "[close bracket]"
	
to say it:
	say "[italic type]"
	
to say bt:
	say "[bold type]"
	
to say rt:
	say "[roman type]"
	
to say lb:
	say "[line break]"
	
to say LB:
	say "[line break]"

	
to say pb:
	say "[paragraph break]"
	
to say q:
	say "[unicode 0063]"[q].
	
to say ex:
	say "[unicode 0033]"[ex].
	
To say fls:
	say "[fixed letter spacing]"[fls].
	
To say FLS:
	say "[fixed letter spacing]"[fls].
	
to say vls:
	say "[variable letter spacing]"[vls].
	
to say VLS:
	say "[variable letter spacing]"[vls].
	
to say spc:
	say " ".
	
to say p:
	say "[fls][bk]PAGE[cb]".
	
to say pc:
	say "[fls][bk]/PAGE[cb][vls]"
	
to say oc:
	say "[fls][bk]CODE[cb][fls]"
	
to say OC:
	say "[fls][bk]CODE[cb][fls]"
	
to say cc:
	say "[fls][bk]/CODE[cb][vls]"
	
to say CC:
	say "[fls][bk]/CODE[cb][vls]"
	
to say ro:
	say "[fls][bk]REMARK[cb]"
	
to say RO:
	say "[fls][bk]REMARK[cb]"
	
to say rc:
	say "[fls][bk]/REMARK[cb][vls]"
	
to say RC:
	say "[fls][bk]/REMARK[cb][vls]"
	
to say oref:
	say "[fls][bk]REFERENCE[cb]"
	
to say cref:
	say "[fls][bk]/REFERENCE[cb]"
	
section 2 - names for the thief

to say lct:
	say "[one of]thief[or]spider[or]footpad[or]deceiver[or]liar[or]unfather[or]unhusband[or]colonist[or]traitor[or]gruekin[or]grueblood[or]imperialist[or]collaborator[or]dead man[or]murderer[or]revenant[or]lackey[or]stranger[or]landless[or]cur[or]sunless[or]rat[or]snitch[or]blackguard[or]miscreant[or]dissembler[or]ghost[purely at random]".
	
to say uct:
	say "[one of]Thief[or]Spider[or]Footpad[or]Deceiver[or]Liar[or]Unfather[or]Unhusband[or]Colonist[or]Traitor[or]Gruekin[or]Grueblood[or]Imperialist[or]Collaborator[or]Dead man[or]Murderer[or]Revenant[or]Lackey[or]Stranger[or]Landless[or]Cur[or]Sunless[or]Rat[or]Snitch[or]Blackguard[or]Miscreant[or]Dissembler[or]Ghost[purely at random]".
	
to say CAP:
	say "[one of]THIEF[OR]SPIDER[OR]FOOTPAD[OR]DECEIVER[OR]LIAR[OR]UNFATHER[OR]UNHUSBAND[OR]COLONIST[OR]TRAITOR[OR]GRUEKIN[OR]GRUEBLOOD[OR]IMPERIALIST[OR]COLLABORATOR[OR]DEAD MAN[OR]MURDERER[OR]REVENANT[OR]LACKEY[OR]STRANGER[OR]LANDLESS[OR]CUR[OR]SUNLESS[OR]RAT[OR]SNITCH[OR]BLACKGUARD[OR]MISCREANT[OR]DISSEMBLER[OR]GHOST[PURELY AT RANDOM]". 
	


section 999 - stairway secret sauce
	
to say stair substitution:
	if the location is museum entrance:
		try going down instead;
	if the location is the royal non-sequitur:
		try going up instead; 
	if the location is btn rm:
		try going south instead.
	
Chapter 4 - Values

Section 1 - truth states

bannerprint is a truth state that varies.
bannerprint is false.

gamestart is a truth state that varies.
gamestart is usually false.

A person can be sighted.
A person is usually not sighted.

The mended causality is an action that varies.

a person can be a time traveller.
a person is usually not a time traveller.

nString is a text that varies.

Book 4 (universal backdrops)

Part 1 - generic darkness

Chapter 1 - backdrop

GD is a scenery backdrop.
GD is everywhere.
does the player mean doing something when the current action involves GD:
	it is very unlikely.
understand "nondescript / darkness" as GD.
the printed name of gd is "[if the player is in primordial darkness]overwhelming darkness[otherwise]nondescript darkness"
	
Instead of doing anything when the current action involves GD:
	say "It is mere connective tissue between greater, more potent darknesses. It offers no power, unless concealment be power. You must either find or create a source of aphotic magic if you wish to do more than hide.".
	
Chapter 2 - high, natural ceilings

the nc is a scenery backdrop.
understand "ceiling" as nc.
the description of the nc is "The ceiling here is irregular and naturally-formed.".
instead of doing anything other than examining to the nc:
	say "[ro]

HOW UNSUBTLE, [CAP]. I WILL NOT PERMIT YOU TO SABOTAGE, DAMAGE, OR OTHERWISE ACT UPON THE CEILING.

[rc][lb]"

the ac is a scenery backdrop.
understand "ceiling" as ac.
the description of the ac is "The ceiling here is well-made and has endured several earthquakes.".
instead of doing anything other than examining to the ac:
	say "[ro]

HOW UNSUBTLE, [CAP]. I WILL NOT PERMIT YOU TO SABOTAGE, DAMAGE, OR OTHERWISE ACT UPON THE CEILING.

[rc][lb]"


Book 5 - Actions

Part 1 - modified from the standard rules

Chapter 1 - talking and asking

talking to is an action applying to one thing.
understand "talk to [person]" as talking to.
Understand "talk [person]" as talking to.
understand "tell [person]" as talking to.
asking is an action applying to one thing.
understand "ask [something]" as asking.

Before telling something about:
	say "(instead talking to [noun])";
	try talking to the noun instead.
	
Before asking something for something:
	say "(instead asking [noun])";
	try asking the noun instead.
	
Before asking something about:
	say "(instead asking [noun])";
	try asking the noun instead.
	
climbing foolishness is an action applying to two things.
understand "climbing [something] [something]" as climbing foolishness.

instead of climbing foolishness:
	if the noun is a direction:
		try going noun;
	otherwise:
		try climbing the second noun.

instead of climbing a direction:
	try going noun.
	
touching something is fiddling.
taking something is fiddling.
pushing something is fiddling.
pulling something is fiddling.
	
Chapter 2 - taking inventory

The print standard inventory rule is not listed in any rulebook.
The print empty inventory rule is not listed in any rulebook.

Carry out taking inventory (this is the new print inventory rule):
	now all things enclosed by the player are marked for listing;
	if no things enclosed by the player are marked for listing:
		say "[if the player is the thief]You are as naked as you are dead.";
		rule succeeds;
	otherwise if something enclosed by the player is marked for listing:
		say "[if the player is the thief]You name these yours:[lb]";
		now all things carried by the player are unmarked for listing;
	if the outfit is worn by the player:
		now the outfit is marked for listing;
		list the contents of the player, with newlines, indented, including contents, giving inventory information, with extra indentation, listing marked items only;
		now all things are unmarked for listing;
	if the stiletto is enclosed by the player:
		now the stiletto is marked for listing;
		list the contents of the player, with newlines, indented, including contents, giving inventory information, with extra indentation, listing marked items only;
		now all things are unmarked for listing;	
	if the sack is enclosed by the player:
		now the sack is marked for listing;
		now all things enclosed by the sack are marked for listing;
		list the contents of the player, with newlines, indented, including contents, giving inventory information, with extra indentation, listing marked items only;
	now all things are unmarked for listing;
	now all droppable things are marked for listing;
	if the player carries the sack:
		now all things enclosed by the sack are unmarked for listing;
	if the something droppable is carried by the player:
		list the contents of the player, with newlines, indented, including contents, giving inventory information, with extra indentation, listing marked items only;

Chapter 3 - examining multiple things

[deprecated]

Chapter 4 - setting it to

a thing can be settable.
a thing is usually not settable.

check setting it to:
	if the noun is not settable:
		say "You can set a horse to water, but you can't make him drink.

[oc]

A THING CAN BE SETTABLE.
A THING IS USUALLY NOT SETTABLE.

CHECK SETTING IT TO:
[t2][fls]IF THE NOUN IS NOT SETTABLE:
[t2][t2][fls]SAY 'YOU CAN SET A HORSE TO WATER, BUT YOU CAN'T MAKE HIM DRINK.'

[cc][lb]"

Part 2 - aphotic magic

Chapter 1 - general

instead of wielding aphotic magic when the thief is not sighted:
	say "Your words feel intuitively correct, but there is no practical understanding behind them.";
	stop the action.

Chapter 2 - gathering

gathering is an action applying to one thing.
understand "gather [something]" as gathering.
understand "absorb [something]" as gathering.
understand "siphon [something]" as gathering.
understand "gt [something]" as gathering.
gathering is wielding aphotic magic.

Check gathering something that is not aphotic:
	say "(first assasying the [noun])";
	try assaying the noun.
	
Instead of gathering something aphotic when the thief is not tinert:
	say "You may only wield one darkness at a time. Either *DELUMINE* a suitable target or *DISPERSE* the magic into the void."
	
Does the player mean gathering something aphotic:
	it is likely.


	
Chapter 3 - delumining

delumining is an action applying to one thing.
understand "delumine [something]" as delumining.
understand "darken [something]" as delumining.
understand "dk [something]" as delumining.
understand "dl [something]" as delumining.
understand "invest [something]" as delumining.
delumining is wielding aphotic magic.

[instead of the thief delumining something when the current action involves the thief:
	say "As a child of the dark, you shape the darkness. It cannot shape you."]
	
Check delumining when the player is tinert:
	if an aphotic thing is in the location:
		let the target be a random aphotic thing in the location;
		say "(first gathering the [target])";
		try gathering the target;
		continue the action;
	otherwise:
		if the player is in the narrow corridor:
			say "[ro]

MAGIC REQUIRES DARKNESS AND POWER. YOU HAVE ONE, BUT NOT THE OTHER.

NOT ALL DOORS HAVE KEYS, BUT THERE IS A HAMMER FOR EVERY NAIL.

[rc][lb]";
		otherwise:
			say "There is no power without darkness. You must find a source of aphotic magic first.[if the location is btn rm][first time]

[ro]

[CAP], YOU CAN *GATHER* SOME MAGIC IN THE BEAM ROOM, JUST TO THE *NORTH* OF HERE.

SUCH IS THE ANCESTRAL BIRTHRIGHT SHUNNED BY YOUR FAMILY.

[rc][lb][only][end if]";
		stop the action.

Chapter 4 - assaying

assaying is an action applying to one thing.
understand "assay [something]" as assaying.
understand "aa [something]" as assaying.
understand "ass [something]" as assaying.
understand "diagnose [something]" as assaying.
understand "dg [something]" as assaying.
assaying is wielding aphotic magic.

does the player mean assaying the player:
	it is very likely.
	
does the player mean assaying something aphotic:
	it is likely.
	
report assaying something:
	now the noun is assayed.
	
Carry out assaying the player:
	let L be the aphosis of the player;
	say the diagstring corresponding to an aphosis of L in the table of aphoses;
	say line break.
	
Chapter 5 - dispersing

dispersing is an action applying to nothing.
understand "disperse" as dispersing.
understand "divest" as dispersing.
understand "dv" as dispersing.
instead of dispersing when the player is tinert:
	say "You neither had nor have any aphotic power to dispose of.";
	
Carry out dispersing:
	say "Not all forms of aphotic magic are easy to come by. Confirm your decision with a 'yes' or 'no' reply.";
	if the player consents:
		say "Done.";
		now the player is tinert;
	otherwise:
		say "Hold on to the power you have. Yes.";

Part 3 - new mundane actions

Chapter 1 - sheathing

[Understand "sheathe [something]" as a mistake ("[shth]").

Understand "unsheathe [something]" as a mistake ("[shth]").

Understand "draw [something]" as a mistake ("[shth]").

to say shth:
	say "[if the treasury is visited]Big knife comes out, big knife goes in, easier than breath. There is no need to mention the scabbard during our journey.[otherwise]During the course of our journey, you will never need to sheathe or unsheathe anything.".
	
Instead of doing anything when the current action involves the scabbard:
	say "Big knife comes out, big knife goes in, easier than breath. There is no need to mention the scabbard during our journey.".]

Chapter 2 - seeing

Seeing is an action applying to nothing.
Understand "see" as seeing.
Instead of seeing when the thief is not sighted:
	say "Seeing? Is that different from looking?";
	
Instead of seeing when the player is sighted:
	say "You may wish to stop seeing before this story ends, but you will not."
	
Part 4 - informational actions

Chapter 1 - Scoring

use scoring.

the maximum score is 350.

discovered anomalies is a number that varies.
discovered anomalies is 0.
 
After doing something:
	repeat through Table of Demerits:
		if the current action is the action performed entry and turn stamp entry is less than 0:
			now the turn stamp entry is the turn count;
			decrease the score by the point value entry;
	continue the action.
	
after creating a temporal paradox:
	if the paradox is already fulfilled:
		continue the action;
	otherwise:
		let CA be the current action;
		choose row with an anomaly of CA in the table of causal anomalies;
		now the turns passed entry is the turn count;
		increment discovered anomalies;
		continue the action.
		
Before creating a temporal paradox:
	if the paradox is already fulfilled:
		choose row with an anomaly of the current action in the table of causal anomalies;
		say "[oc][pb]Before creating a temporal paradox:[lb][t2][fls]repeat through the Table of Causal Anomalies:[lb][t2][t2][fls]if the current action is the anomaly entry and the turns passed entry is greater than 0:[lb][t2][t2][t2][fls]say failure response entry;[lb][t2][t2][t2][fls]stop the action.[lb][cc][pb]";
		say failure response entry;
		if the current action is fighting the clock:
			continue the action;
		otherwise if the current action is being illuminated:
			if the location is not junction:
				now the player is in junction;
			now the dorn is not imminent;
			now BI is false;
			stop the action;
		otherwise if the current action is teasing the shadow dorn:
			if the location is not junction:
				now the player is in Junction;
			now the dorn is not imminent;
			stop the action;
		otherwise if the current action is being stumped by the puzzle:
			now the player is in the royal non-sequitur;
			stop the action;
		otherwise:
			stop the action;
		stop the action;
	otherwise:
		continue the action;
				
 
Understand "full score" or "full" or "fs" as requesting the complete score. Requesting the complete score is an action out of world.
 
Check requesting the complete score:
	if the score is 350, say "You have yet to embrace the darkness here." instead.
 
Carry out requesting the complete score (this is the full score rule):
	say "[bt]The following actions have affected your score:[rt]";
	sort the Table of Demerits in turn stamp order;
	repeat through the Table of Demerits:
		if the turn stamp entry is greater than 0:
			say "[lb][tab][description entry]: [point value entry] points";
	say line break.
	
Chapter 2 - temporal paradoxes
 
counting anomalies is an action out of world applying to nothing.
understand "count anomalies" as counting anomalies.
understand "ca" as counting anomalies.
 
Check counting anomalies:
	if the discovered anomalies is 0, say "You have yet to uncover any causal anomalies." instead.
 
Carry out counting anomalies (this is the anomaly counting rule):
	say "[bt]You have failed to end this story in [discovered anomalies in words] of [number of rows in table of causal anomalies in words] possible ways:[rt]";
	sort the Table of Causal Anomalies in turns passed order;
	repeat through the Table of Causal Anomalies:
		if the turns passed entry is greater than 0:
			say "[line break][tab][description entry]";
	say line break.

Chapter 1 (TBD)

Book 6 (Rules)

Book 7 (Global Things, Kinds, etc)

Part 1 - Kinds

Chapter 1 - Discussion

A Discussion is a kind of value.

Volume 2 (Actions and Action Processing

Book 1 (Actual Actions)

Chapter 1 (Completely New)

Book 2 (out of world)

Section 1 (Status Line)

Include
(-

[ InitStatusWindow sty;
 if (gg_statuswin == 0) {
	statuswin_cursize = statuswin_size;
	if (0) {
		for (sty=0: sty<style_NUMSTYLES: sty++)
			glk_stylehint_set(wintype_TextGrid, sty, stylehint_ReverseColor, 1);
	}
	gg_statuswin =
		glk_window_open(gg_mainwin, winmethod_Above | winmethod_Fixed, statuswin_cursize, wintype_TextGrid, GG_STATUSWIN_ROCK);
}
];
-)

To close the/-- status window:
	(- if (gg_statuswin) glk_window_close(gg_statuswin, 0); gg_statuswin = 0; -)

hiding the status line is an action applying to nothing.
revealing the status line is an action applying to nothing.

To initialize/initialise the/-- status window:
	(- InitStatusWindow(); -)

Carry out hiding the status line:
	close the status window;

Carry out revealing the status line:
	open the status window;
	
To open the/-- status window:
	initialize the status window;
	
Section 2 - nouns

nouning is an action out of world applying to nothing.
understand "things" and "nn" and "t" as nouning.

carry out nouning:
	say "[bt]You sense the following things nearby:[rt]";
	repeat with items running through things enclosed by the location:
		if items is visible:
			say line break;
			say tab;
			if items is the player:
				say "you, the thief - protagonist";
			otherwise if items is a door:
				if the door is busted:
					do nothing;
				otherwise:
					say items;
			otherwise if items is backdrop:
				say "[items] - backdrop";
			otherwise if items is scenery:
				say "[items] - scenery";
			otherwise if items is enclosed by the thief:
				say "[items] - in inventory";
			otherwise:
				say "[items] - other item(s)";
	say line break.


[report nouning:
	if the number of things enclosed by the player is zero:
		stop the action;
	repeat with goods running through things enclosed by the player:
		say "[bt]The following things are carried by you:[rt]";
		if goods is a container:
			say "[lb][tab][goods] - container";
		otherwise if goods is in a container:
			say "[lb][tab][goods] - contained";
		otherwise:
			say "[lb][tab][goods] - carried";
	say "[lb]".]
			



	
Chapter 1 (Modified, general responses to multiple actions)

Book 3 (Player Characters)



Chapter 1 (the thief)

The thief is a male person.
The player is the thief.
The printed name of the thief is "You, thief".
Understand "thief" as the thief.
The thief has an aphosis.
The thief is tinert.
The description of the thief is "[if the thief is in primordial darkness]You don't know if there is a 'you' or a 'here', here.[otherwise if the outfit is not worn by the thief]Naked. Cold and white as cave salamanders.[otherwise if the sack is not carried by the player]Pale. Dead. Hooded and armed.[otherwise]Pale. Dead. Stiletto in one hand, sack in the other.".
The carrying capacity of the thief is 4.

Volume 3 (conversation)

Book 1 - general

does the player mean talking to the dungeon master:
	it is likely.

Carry out talking to the dungeon master:
	if the thief is not introduced to the dungeon master:
		switch to cyoa at dm introduction.

A person can be introduced to the dungeon master.
A person is rarely introduced to the dungeon master.

A person can be aware of the implementors.
A person is rarely aware of the implementors.

A person can be aware of Drew Cook.
A person is rarely aware of Drew Cook.

A person can be aware of the year.
A person is rarely aware of the year.

A person can be aware of his powers.
A person is rarely aware of his powers.

Book 2 - the dungeon master in the treasury

Part 1 - DM introduction

DM introduction is a page.



"[fls][bk]CODE[cb]

carry out talking to the dungeon master:
[lb][t2][fls]if the thief is not introduced to the dungeon master:
[lb][t2][t2][fls]switch to CYOA at dm introduction.

[bk]/CODE[cb]

[vls]The old eyes twinkle with... what? Mischief? Derision? Murderous glee, perhaps. No, it's familiarity. His eyes gleam with unreciprocated familiarity.

'How does it feel,' he smiles, 'to return to your ancestral home?'"

A page-toggle for DM introduction:
	now the thief is introduced to the dungeon master.
	
Part 2 - Ancestral Home

Ancestral Home is a page. The Cdesc is "[p]ANCESTRAL HOME[pc]". It is for DM introduction.
"'Neither your wife nor your child could make an uplander of you. You belonged nowhere to no one. Even death refused you.

'But now you have returned,' he gestures ironically, 'to the wealth and might of the underground.'".

Chapter 1 - Wife

Wife is a page. it is for ancestral home. the cdesc is "[p]WIFE[pc]".
"'She and your son passed into the beyonds 179 years ago. Such was the will of the Demiurge.'".

Section 1 - Demiurge

Demiurge is a page. It is for Wife. It is for Empty Waste. It is for Responsibility. it is for underground. it is an end-page.
"'The Demiurge is the author of all that happens and is. I cannot help but do his will, and neither can you.

'He commands that you travel an impossible distance to an impossible confrontation. I am bound by geas to say nothing else. Do not worry,' his laugh falls through the air like powdered glass, 'your story will find you wherever you go.'[if the player is not wearing the outfit][pb]The old man looks at you. 'Get dressed, you fool.'[pb]You quickly don the outfit, which fits perfectly, and sheathe the long stiletto. [otherwise][pb][end if]The old man waves his staff at you, and a potent mechokinetic wave shoves you through a bronze door in the northern wall. It clangs shut behind you with a final-sounding clang[dot][dot][dot][run paragraph on]

[oc]

A page-toggle for DEMIURGE:
[lb][t2][fls]now the thief is in the cage.

[cc]".

Rule for choice-displaying Demiurge:
	if the current page is Wife:
		say "[p]DEMIURGE[q][pc]";
	else if the current page is Empty Waste:
		say "[p]DEMIURGE[q][pc]";
	else if the current page is Responsibility:
		say "[p]DEMIURGE[q][pc]";
	else if the current page is Underground:
		say "[p]DEMIURGE[q][pc]".
		
A page-toggle for Demiurge:
	move the player to the cage, without printing a room description;
	if the outfit is not worn by the player:
		now the player is wearing the outfit;
		now the stiletto is carried by the player;
		
Chapter 2 - Underground

The underground is a page. The cdesc is "[p]UNDERGROUND[pc]". It is for Ancestral Home.
"'Like death, this place does not claim you. And yet, the god of these empty lands, the Demiurge, has sought you out.'"
 
Part 3 - Who are you

Who's the DM is a page. The Cdesc is "[p]AGED THAUMATURGE[pc]". It is for DM introduction.
"He looks through you. 'I am lord of this empty waste, this once-thriving land of wealth and discovery.'"

Chapter 1 - Responsibility

Responsibility is a page. The Cdesc is "[p]WEALTH[pc]". It is for Who's the DM.
"'This land was once filled will treasures and riches. In those days, I was as much a thief as you.

'That Age of Magic now passes out of memory. The Age of Science has come, and, with it, the Demiurge.'".

Chapter 2 - Empty Waste

Empty Waste is a page. The Cdesc is "[p]EMPTY WASTE[pc]". It is for Who's the DM.
"'You were murdered too late, thief. What remains of your Empire?'

He leans heavily over his staff, shaking his head.

'It no longer matters. The Implementers are long gone, and the Demiurge is a god of empty worlds, of emptiness.'".


Volume 4 - opening

Book 1 (when play begins)

Rule for printing the banner text when bannerprint is false: do nothing.

When play begins:
	now mn_master_table is table of invisiclues;
	try hiding the status line;
	say "
	
The help system contains instructions for using magic in this game, as well as providing hints and other instructions. First-time players are strongly encouraged to have a look before play. 

Commands, words, and phrases than are meant to be typed in verbatim are printed in capital letters and bracketed by the asterisk ('*') symbol. For instance, the *HELP* system can be accessed by typing 'help' at the command prompt.

Press any key to continue.";
	wait for any key;
	say "




Everything, the whole world, dark. Cold. Smoke, exertion, resentment. A crowd. A woman shrieking.

'Get up, gruekin.' Ribs sparking under the skin. A blooming whiteness behind your eyes. 'Up, you twice-cursed running dog.'

Smoke and the crack of fatwood.
Your son, nearby, crying.
Your wife, speaking through missing teeth.

'Not my son,' she says. 'Not my child.' She points at you: 'Him. He's the one you want.' It's true. You are the Emperor's Second Spymaster.

You bash the two men holding you together, then punch the leader's windpipe. A long stiletto falls from his twitching hand. It feels good, holding it. You move toward your wife and son, but you already know that you can't save them. Only seven fall before you turn to see your son's head bounce against the cobbles.

It must be true what the Enchanters say: there is a grand system, a structure, at work in everything.

This is the last time you will see your wife alive: watching her only child die. Someone behind you laughs. 'I'm glad you had a chance to see that.'

More laughing[dot]
[lb]Different voices[dot]
[lb]Different laughters[dot]
[lb]And then, dark.

The kind of dark they make nothing out of.[lb]".


When play begins:
	say "*Press Any Key to Continue*[pb]";
	say "[lb][oc][pb]";
	say "[fls]wait for any key;[lb]";
	if prod is true:
		wait for any key;
	say "[fls]try revealing the status line;";
	try revealing the status line;
	say "[fls]now bannerprint is true;";
	now bannerprint is true;
	say "[lb][fls]now gamestart is true;";
	now gamestart is true;
	say "[lb][fls]now the player is the thief.";
	say "[lb][fls][bk]/CODE[cb][pb][pb]";
	move the player to primordial darkness, without printing a room description;
	try silently switching score notification on;
	now the score is 350;

Book 2 (Zork 3 in the future)

Book 3 (regional information)

Chapter 1 - everywhere and nowhere

Section 1 - the staging area

the staging area is a room.
the thief is in the staging area.

Chapter 2 - dressed stone region

The stone hall is a region.
The narrow corridor is in the stone hall.

Chapter 3 - guardian hallway

guardian hallway is a region.
The guardian hallway is in the stone hall.

Chapter 3 - bracket

bracket is a region.
bracket is in the guardian hallway.

Chapter 4 - the future beyond the DM's area

the greater earthquake territory is a region.

Chapter 5 - the monstrous west

the monstrous west is a region.

Book 4 - Rooms, things, and actions

Part 1 - Primordial Darkness

Chapter 1 - general
	
Chapter 2 - Description

Primordial Darkness is a room.
The printed name of Primordial Darkness is "[first time][lb][only]An Originating Darkness".

The description of primordial darkness is "[one of]Perhaps the darknesses you have known are impersonators, and this, the real one, has come for you at last.[or]You try to reach out and feel the floor with your hands, but there seems to be no floor.[or]You try to grasp one hand with the other, but you can't find your hands.[or]You cannot know, or even reach the edges of knowing, how long you have been here.[or]You are in a place where you are not.[stopping]"

Chapter 3 - Nouns

[the dark setting is a scenery backdrop in Primordial Darkness.
understand "dark" and "darkness" and "floor" and "ceiling" and "wall" and "room" as the dark setting.]


Chapter 4 - Actions

Section 1 - a general response

instead of doing anything in primordial darkness:
	if revealing the status line:
		continue the action;
	otherwise if examining the player:
		say "You are not sure where you end and the darkness begins.";
		stop the action;
	otherwise:
		say  "[one of]Perhaps the darknesses you have known are impersonators, and this, the real one, has come for you at last.[or]You try to reach out and feel the floor with your hands, but there seems to be no floor.[or]You try to grasp one hand with the other, but you can't find your hands.[or]You cannot know, or even reach the edges of knowing, how long you have been here.[or]You are in a place where you are not.[stopping]".
	
[Every turn when player is in primordial darkness for the first time:
	say "[oc]

Every turn when player is in primordial darkness for the first time:
	say]
	
Book 5 (The treasury)

part 0 - heavy wooden door

The heavy wooden door is a door. it is south of the treasury and north of the cage. the heavy wooden door is scenery.

before doing anything when the current action involves the heavy wooden door:
	try going east instead.

Part 1 general rules

Book 6 - arrival in the treasury

Count of turns in the darkness is a number that varies. Count of turns in the darkness is 0.

Every turn when the player is in primordial darkness:
	increment the count of turns in the darkness;
	if the count of turns in the darkness is greater than zero and the count of turns in the darkness is less than four:
		say "[oc]

EVERY TURN WHEN THE PLAYER IS IN PRIMORDIAL DARKNESS:
[lb][t2][fls]INCREMENT THE COUNT OF TURNS IN THE DARKNESS.

[cc][lb]";
	otherwise if the count of turns in the darkness is four:
		say "You feel a shift in your fundamental makeup, as if remade entire, as if poured hot into a die. You know you are underground.

To know that is your birthright.

[fls][bk]CODE[cb][pb][fls]MOVE THE THIEF TO THE TREASURY, WITHOUT PRINTING A ROOM DESCRIPTION;[pb][bk]/CODE[cb][vls][lb]";
		move the thief to the treasury, without printing a room description;
		say "An old man leans over a gnarled wooden staff. 'Arise,' he says, amused. 'Arise, little ghost.'

You kneel, naked, at the center of a circle, hand-drawn in chalk, on a smooth stone floor. It is hard to... is it breathing that you labor to do?

'Up, up, he laughs. The dead are anything but modest.' You stand, neither cold nor hot. You are not, you realize, anything. Neither modest nor immodest. You know without smelling that smoke is on the air and feel a flame's heat without feeling. 'Do you know me, revenant?'

He is a young, old man, with eyes like bluelit scryboxes. You answer him with a croak.

'Well said, thief.' His laugh is wet mud in full sun. 'I name you other names: traitor, gruekin, landless, stranger. Unfather, unhusband. Murderer. Lackey.'

These names, you know, are deserved.

'You emerge from a dark that even you cannot know. That was the fate you earned, hegemon.'

Somewhere beyond the walls, you hear[em]without hearing[em]the whoosh of fire devouring air.";
		try looking;

Book 7 - the timer

Count of turns in the treasury is a number that varies.
Count of turns in the treasury is zero.

every turn when the player is in the treasury and the player is not introduced to the dungeon master (this is the turns in the treasury rule):
	if the count of turns in the treasury is zero:
		say "The old man's gaze sweeps slowly from your eyes to the long knife with an amused intensity.";
	if the count of turns in the treasury is less than three:
		increment count of turns in the treasury;

Every turn when the player is in the treasury and the player is not introduced to the dungeon master and count of turns in the treasury is less than three and count of turns in the treasury is greater than zero (this is the treasury countdown rule):
	say "[fls][bk]CODE[cb]
[pb][fls]Every turn when the player is in the treasury (this is the treasury countdown rule):
[lb][t2][fls]Increment count of turns in the treasury;
[pb][bk]/CODE[cb]

[vls][one of]The ancient wizard examines you closely, as if looking for dents on a crate of vegetables.[or]The old man looks at the jeweled ring gracing his right hand.[or][run paragraph on][stopping]";

Every turn when the player is in the treasury and the player is not introduced to the dungeon master and count of turns in the treasury is three:
	say "The Dungeon Master taps the floor with his gnarled staff. 'Speak to me, thief. I wish to celebrate our reuinion.'";
	now the count of turns in the treasury is 999;
	if the thief is not introduced to the dungeon master:
		switch to cyoa at dm introduction.
	
Book 8 - Room Description

Treasury is a room.
The printed name of treasury is "[if the player is introduced to the dungeon master][run paragraph on][otherwise]Treasury".
The description of the treasury is "[one of]Your eyes, still adapting, fix on a pile of coins taller than you are. Paintings, maps, sculptures. Gems everywhere. The mounted head of a hellhound hangs on the wall.

[ro]

THERE IS ALWAYS A HELLHOUND.

[rc]

This is a treasury of some sort, wealth that escaped the notice of colonial governors and court diviners. Every type of treasure is either here or else represented by the documents of financial bureaucracies.[or]This room contains a stunning concentration of wealth: sculptures, gems, paintings, and coins heaped nearly to the ceiling.

The head of a hellhound is mounted to the wall, and its gaze seems focused on you.[stopping]".

Rule for writing a paragraph about the outfit:
	if the player is introduced to the dungeon master:
		now the outfit is mentioned;
		now the stiletto is mentioned;
	otherwise:
		say "Clothing suitable for spycraft is neatly laid out before you. It consists of a brown tunic and pants, complemented by a dark gray cloak. A pair of low, soft-soled boots finish out the look. The ensemble, the working attire of a thief or spy, suits you. Is suited to you. A famliar-looking stiletto has been placed diagonally atop the folded garments.";
	now the stiletto is mentioned.

Rule for writing a paragraph about the dungeon master:
	now the dungeon master is mentioned.

Book 9 (treasury nouns)

Section 1 

Treasure is a scenery backdrop in the treasury.
Understand "treasures" and "wealth" as treasure.
Instead of doing anything other than examining to the treasure:
	try taking the painting.
	
[a thing can be a valuable. a thing is usually not valuable.]

	
The description of treasure is "The treasures here rival the wealth of the Imperial Vaults.".

Part 1 - the stiletto

The stiletto is in the treasury.
the stiletto is precious.
Understand "knife / dagger / sharp / tooth / blade / needle / stiletto" as the stiletto. Understand "grue's tooth" as the stiletto.
The printed name of the stiletto is "grue's tooth".
The description of the stiletto is "[if the stiletto is not carried by the player]It is the weapon you held even as you died. It has traveled far to be here.[otherwise]Even though you have not known each-other long, the stiletto feels [it]right[rt] in your hands. Its narrow, needle-like blade is the work of a different age, and you sense magic in its construction.".
	


Part 2 - the paintings

The painting is a scenery object in the treasury.
the painting is a valuable.
Understand "portraits" and "portrait" and "van frob" and "frob" and "rembozzle" and "de vorple" and "flathead" and "flathead dynasty" and "dynasty" and "paintings" as the painting.

The description of the painting is "Among the paintings, you spy portraits of historic figures dating back to the beginning of the Flathead Dynasty, long the subject of songs, plays, and literature. Their artists are all recognized as the greatest in Quendor's history: Van Frob, Rembozzle, de Vorple, and others.".

Part 3 - the maps

The map is in the treasury.
The map is scenery.
The map is a valuable.
Understand "flathead mountains" and "quendor" and "rocs" and "mountains" and "lands" and "lands beyond" and "lands beyond the flathead mountains" and "maps" as the map.

The description of the map is "Some of these maps are valuable for their utility, identifying as they do treasure troves and scenic views. Others, on the other hand, are art objects from previous ages. One ancient map concerns the lands beyond the Flathead Mountains. This uncivilized corner of Quendor is labeled in elegant script: 'Here Be Rocs.'".

Part 4 - the sculptures

The sculptures is a scenery object in the treasury.
The sculptures is a valuable.
The sculptures are a plural-named thing.
Understand "statues" and "statue" and "michelangebloit" and "praxithrax" and "berinibar" and "Entharion" and "entharion the wise" and "wise" and "frambozz" and "frambozz the unlucky" and "unlucky" and "Venus" and "flathead" and "venus de flathead" and "sculpture" as the sculptures.

The description of the sculptures is "The sculptures are priceless works by the master craftsmen of another age: Michelangebloit, Praxithrax, Berinibar, and others still. The subjects include Entharion the Wise, Frambozz the Unlucky, and Venus de Flathead.".

Part 5 - the gems

The gem is a scenery object in the treasury.
The gem is a valuable.
Understand "jewel" and "jewels" and "ruby" and "rubies" and "diamond" and "diamonds" and "gems" as gem.
The description of the gem is "The gems embody a widespread misunderstanding regarding the value of things.".

Part 6 - the coins

The coin is a scenery object in the treasury.
The coin is a valuable.
Understand "pile" and "piles" and "coins" as coin.
The description of the coin is "There are at least three[em]it's a large, cluttered room[em]cyclops-sized piles of ancient currencies, all stamped in silver or gold. Like the other treasures here, the coins are unable to hold your interest.".

Part 7 - the hellhound

The hellhound head is a scenery object in the treasury.
Understand "hound" and "hell" and "beast" and "monster" and "hellhound's" and "hellhound's head" as the hellhound head.
The description of the hellhound head is "This hellhound's head, stuffed with magically treated, inflammable granola, may be one of a kind. Such beasts are part fire, and only their magical nature prevents them from immediately burning to ash. Once their life source dissipates, they are almost always reduced to soot in a matter of seconds. The enchanter who preserved this head would have been quite powerful and just as quick.".

Instead of doing anything other than examining when the current action involves the hellhound head:
	say "There is something uncanny about the hellhound's head, as if it could still bite something within reach.".
	
part 8 - the documents

documents are a scenery object in the treasury.
the documents are a valuable.
the documents are a plural-named thing.
the description of the documents is "Many financial documents are piled around the room. Some certify ownership of land, some prove ownership of Frobozzco stock. They fail to hold your interest.".

Part 8 - The clothing

Chapter 1 - the outfit

The outfit is in the treasury.
the outfit is precious.
The outfit is wearable.
The printed name of the outfit is "spymaster's robe of state".
Understand "clothing" and "clothes" and "garb" and "thief's garb" and "spymaster's / uniform / of / state" as the outfit.
The description of the outfit is "This is an outfit suitable for spycraft, dyed dark gray and brown.[if the outfit is not worn by the player] Perhaps you should *WEAR THE OUTFIT*[otherwise]The clothing fits you perfectly, and blends well with shadows.".

the pieces is part of the outfit.
understand "tunic" and "pants" and "boots" and "soft boots" and "cloak" and "belt" and "hood" as the pieces.

Instead of doing anything other than examining to the pieces when the outfit is not worn by the player:
	say "There is no need to refer to individual pieces of clothing. In fact, the only thing you can do with the clothing is *WEAR THE OUTFIT*.".
	
Instead of doing anything to the pieces when the outfit is worn by the player:
	say "There is no need to refer to the individual parts of the outfil. In fact, now that you're dressed, you may as well leave your clothes alone.".
	
Instead of taking off the outfit:
	say "While you feel indifferent regarding nudity, you want potential foes to take you seriously.".

[Chapter 2 - the scabbard

the scabbard is a container.
The scabbard is in the treasury.
The scabbard is wearable.
Understand "sheath" as the scabbard.
The description of the scabbard is "A utilitarian sheath for keeping your stiletto near at hand."

Instead of doing anything when the current action involves the scabbard:
	say "[oc]

Instead of doing anything when the current action involves the scabbard:
[lb][t2][fls]There is no need to refer to the scabbard in the course of this story.

Really!

[cc][lb]";

Rule for writing a paragraph about the scabbard:
	now the scabbard is mentioned.]

Book 10 - treasury people

Part 1 - The Dungeon Master

The dungeon master is in the treasury.
The dungeon master is a male person.
The printed name of the dungeon master is "aged thaumaturge".
Understand "old man" and "aged" and "thaumaturge" and "wizard" and "dungeon master" and "master" and "dm" and "man" and "mage" and "engineer" as the dungeon master.

The description of the dungeon master is "This aged thaumaturge exudes an air of youthful vitality despite his appearance. You feel that you might know him, even though you know that you do not. He wears a dark mantle and a simple golden amulet.".

Instead of doing anything other than examining or talking to or asking to the dungeon master:
	say "The old man is, despite his humble appearance, a mighty wizard in his place of power. You may be cursed and unliving, but even the dead can know pain.".

Chapter 1 - the mantle and amulet

The dungeon master is wearing the mantle.
The description of the mantle is "Even though the mantle is undecorated, it somehow confers a sense of authority or prestige. It is fashioned from dark, supple cloth."

The dungeon master is wearing the amulet.
The description of the amulet is "The amulet is simple and unadorned, and it appears to signify office or status.".

Instead of doing anything other than examining to something that is worn by the dungeon master:
	try touching the dungeon master.
	
The dungeon master is wearing the royal ring.
Understand "royal / red / ruby / ring" as the royal ring.
The description of the royal ring is "It is a simple golden band."


Book 11 (treasury actions)

Part 1 - general
	
Instead of doing anything other than examining or taking to a valuable in the treasury:
	say "Not only are the treasures not [it]yours[rt]; they aren't [it]for you[rt]. You cannot bring yourself to care about them.".
		
Part 2 - taking

The standard report taking rule does nothing when the noun is the stiletto.

instead of taking the outfit:
	try taking the stiletto.

Before wearing the outfit:
	try taking the stiletto;
	stop the action.

Carry out taking the stiletto:
	say "You pick up the stiletto lying atop the outfit. It is the same one: keen as a grue's tooth and perfectly balanced. This is the craftsmanship of another age, long lost to peoples above and below ground. How the ringleader of a seditous mob came to possess such a priceless artifact will forever be a mystery. The wizard, who may be older than the knife, smiles.

'That is yours, thief. It has always been yours.'

Next, you quickly gather the outfit and put it on. Everything fits perfectly, as if made by the Emperor's tailor himself.";
	now the outfit is worn by the thief;

Instead of dropping the stiletto:
	say "No. Even the dead must protect themselves.".
	
instead of inserting the stiletto into something:
	say "No. Even the dead must protect themselves.".
		
	
attacking is making violence.

[after doing something when the current action involves the stiletto and the stiletto is carried by the player:
	if not making violence:
		try inserting the stiletto into the scabbard.]

Instead of taking a valuable in the treasury:
	say "Even if you remain a thief, you long ago forsook treasure for power. What good can it do you here, now?".
	
dropping is letting go.
giving something to is letting go.
inserting something into is letting go.
putting something on is letting go.
pushing something to is letting go.

instead of going when the player is not introduced to the dungeon master:
	if the player is not wearing the outfit:
		say "Someone as dead as you are will accomplish little in the world clothed, and you are naked.";
	otherwise:
		say "The old man seems to know what has happened to you. Consider trying to *TALK TO THE DUNGEON MASTER* before leaving."
.



Volume 5 (OEW maps)

Volume 6 (Endgame)

Volume 7 (Hints)

test dm with 
"gonear treasury /
talk to dungeon master"

Volume 8 - The Age of Magic Ends

Book 1 - Geographies

Part 1 - Lakeshore

Chapter 1 - defined

lakeshore is a region.

Chapter 2 - backdrops

Book 2 - cage

Cage is a room.
Cage is south of the heavy wooden door.
Cage is north of ncorridor.
The printed name of cage is "Prison Cell #8".
The description of cage is "You are in a bare prison cell suspended above a bottomless lake of fire. The air surrounding the cage wobbles and smokes, but the space within might be safe for the living.".

Every turn when the player is in cage:
	say "The cell lurches toward an invisible curve, and stops upon rounding it. The door opens southward, and you step through.

[oc]

MOVE THE PLAYER TO THE NORTHERN CORRIDOR

[cc][lb]";
	now the player is in NCorridor;
	say "[oc]

MOVE THE PLAYER TO THE WESTERN CORRIDOR

[cc][lb]";
	move the player to wcorridor;
	say "[oc]

MOVE THE PLAYER TO THE SOUTHERN CORRIDOR

[cc][lb]";
	move the player to scorridor;
	say "[oc]

MOVE THE PLAYER TO THE NARROW CORRIDOR

[cc][lb]";	
	move the player to Narrow Corridor.
	

Book 3 - NCorridor

Part 1 - Decscription and other general stuff

NCorridor is a room.
Ncorridor is in lakeshore.
The printed name of NCorridor is "Northern Corridor".
The description of NCorridor is  "A rocky shelf above a lake of fire. Smoke and smeared air. A mass of wealth and science suspended at its center.

Earthquake-tossed marble and stone at the mouth of an eastern path, marble-clad smoke to the west.

The ceiling above you shakes, throwing gravel sparks from its stone flame. You hurry west."


WCorridor is west of NCorridor.


Part 2 - Nouns


Part 3 - Verbs

Chapter 1 - going

Book 4 - West corridor

The description of WCorridor is "East beyond pocked and veined marble lies the pit."

Wcorridor is in lakeshore.
The printed name of WCorridor is "West Corridor".

NCorridor is north of Wcorridor.
WCorridor is west of Scorridor.

Book 5 - South Corridor

Scorridor is a room.
The printed name of scorridor is "Southern Corridor".
scorridor is in lakeshore.
SCorridor is east of Wcorridor.
WCorridor is west of SCorridor.
the description of scorridor is "A perpendicularity at the south end of the lake. Eastward lies a place, unplaced.".

Book 6 - narrow corridor

The Narrow Corridor is a room.
Understand "nc" as the narrow corridor.
The printed name of the narrow corridor is "Narrow Corridor".
The Narrow Corridor is south of SCorridor.
The description of the narrow corridor is "Dressed stone and narrowness. [if the thief is not sighted]A plain wooden door closes to the south[otherwise]Southward, a plain wooden door fails to hold back the darkness[end if].".

Chapter 1 - rules in the narrow corridor

Before doing anything when the player is in the narrow corridor for the second time:
	say "Everything above and below shakes, and the marble hallway behind you falls over itself in a jumble of stone. Light, which once emerged from an indeteriminate source, blinks before its dying


[ro]

[CAP], MAGIC DIES TODAY, AND THIS PLACE WITH IT. THE AGE OF SCIENCE WILL UNMAKE YOU BEFORE YOU HAVE A CHANCE TO DIE.

THAT END WOULD SUIT YOU, BUT IT WILL NOT SUIT ME.

[rc]


hand to steady yourself.";
stop the action.


Before doing anything when the player is in the narrow corridor for the third time:
	say "[oc]

INSTEAD OF DOING ANYTHING WHEN THE PLAYER IS IN THE NARROW CORRIDOR FOR THE SECOND TIME:
[lb][t2][fls]say 'THE DARKNESS IS A PITCH BEYOND PITCH, BUT YOUR EYES[bk]UNICODE 8212[cb]IS IT YOUR EYES[q][bk]UNICODE 8212[cb]ARE ADJUSTING.'

[cc][lb]";
stop the action.

Before doing anything when the player is in the narrow corridor for the fourth time:
	say "Like an insect flying under glass, th


[ro]

DID YOU COME THIS WAY, THIS TIME, THESE YEARS, TO CONTEND WITH A HOLE IN THE LIGHT?

[rc]


ch outcomes are matters of degree only.

The darkness slowly settles in the places left by the light. Places in your throat, in the bones of your face, in you. The world, unlit as anything, returns. It comes as a series of spaces, measured in vacated rock.

The newly-fallen rockfall at the north end of the cave is a chaos of stones, an adirectional pile of vectors. The remaining walls are made of dressed stone, perfectly fitted.

The door at the southern end of the hall is visible again, as is its little window. It strives heroically to hold back the sunlessness beyond its frame, but it cannot keep you from it.


[ro]

NO DOOR HAS EVER KEPT THE GRUES AT BAY. HOW MUCH HUMANITY DID DEATH LEAVE YOU?

[rc][lb]";
	now the thief is sighted;
	now the description of the narrow corridor is "The newly-fallen rockfall at the north end of the cave is a chaos of stones, an adirectional pile of vectors. The remaining walls are made of dressed stone, perfectly fitted.

[if the pwd is closed]The door and it's little window stand at the southern end of this hall. For all its striving, it cannot forever hold a sunlessness at bay.[otherwise]The door that once stood to the south is less than a memory, yet more than a never.";
	now the description of the pwd is "[if the PWDwindow is closed]A levee separating one darkness from another. It wears a small sliding window on its chest[otherwise if the pwd is closed]A wave of nothing, visible through the open window, crashes against it[otherwise if the pwd is open and the thief is in the narrow corridor]The empty frame is the only indication that a door was ever there[otherwise]If only a confusion of stone were a door[end if]."


Chapter 2 - nouns in the narrow corridor

Section 1 - the door

the pwd is a door.
the pwd is deluminable.
the pwd is south of the narrow corridor.
the pwd is north of the DE.
the printed name of pwd is "plain wooden door".
understand "plain / wooden / door" and "doorway" as pwd.
the pwd is closed.


the description of the pwd is "[if the thief is sighted]The door has a small sliding window at eye level[otherwise]It is as useless as a door that cannot open[end if].[if the pwdwindow is closed] A small closed window tempts just as as red buttons do[end if][dot]"

rule for writing a paragraph about the pwd:
	now the pwd is mentioned.
	
instead of opening the pwd:
	if the player is in narrow corridor:
		if the thief is not sighted:
			do nothing;
			continue the action;
		otherwise if the thief is sighted:
			say "A door one that stops nothing is no door at all. You will not budge it with the strength of your limbs." instead;
	otherwise if the player is in the DE:
		say "The rock-filled doorway has a future at your back, but you must live forwards.".
		
instead of doing anything other than wielding aphotic magic or examining or opening to the pwd when the pwd is not busted:
	say "The door has proven resistant to your charms.[first time]

[ro]

[CAP], THE DEMIURGE GRANTS YOU THE POWER OF YOUR ANCESTORS: APHOTIC MAGIC. EVEN THOUGH YOU FORSOOK YOUR PEOPLE FOR PRIVILEGE AND POWER, THEIR SECRET IS YOURS.

LOOK BEYOND THE WINDOW.

[rc][lb][only]"

Section 2 - the window

the PWDwindow is part of the pwd.
the PWDwindow can be openable.
the PWDwindow is openable.
the PWDwindow can be open.
the PWDwindow is closed.
the printed name of the pwdwindow is "small sliding window".
understand "small / sliding / window" as the PWDwindow.
the description of the PWDwindow is "[if the pwdwindow is open]A window into space and dark[otherwise]Closed until opened[end if].".
instead of doing anything other than wielding aphotic magic or examining or opening or closing or searching to the pwdwindow:
	say "The window's name implies its purpose.".

Section 3 - the dressed stone

the dressed stone is a scenery backdrop.
the dressed stone is in the stone hall.
understand "walls" and "floors" and "ceilings" and "ceiling" and "wall" and "floor" and "stones" and "cut / stone" as the dressed stone.

The description of the dressed stone is "[if the thief is in the narrow corridor]Close-fitted and earthquake-resistant.[otherwise]This hallway, like the narrow corridor behind you, is constructed from finely-cut stone."

Instead of doing anything other than examining or delumining to the dressed stone:
	say "[oc]
	
INSTEAD OF DOING ANYTHING OTHER THAN EXAMINING OR DELUMINING TO THE DRESSED STONE:
[lb][t2][fls]SAY 'THE DRESSED STONE IS IMPERVIOUS TO THE INSULTS OF TIME. AND YOU.'

[cc][lb]".

section 4 - the crashing darkness

the crashing darkness is a backdrop.
The crashing darkness is not scenery.
the crashing darkness is aphotic.
the description of the crashing darkness is "This darkness is more something to know than it is something to see. *ASSAY* it to gain insight into it.".

rule for writing a paragraph about the crashing darkness when the player is in the narrow corridor:
	say "[if the crashing darkness is not assayed]The darkness breaks in waves against its wooden shore. *ASSAY THE CRASHING DARKNESS* to learn its secrets.[otherwise if the player is tinert]Through the window, the *CRASHING DARKNESS* rises, falls against the door, then rises again. You could *GATHER THE CRASHING DARKNESS*, just as your ancestors of old once did.[otherwise]The *CRASHING DARKNESS* breaks against the door in unceasing waves. You have gathered some of it unto yourself, but an entire sea of it remains beyond the door and its window."

Chapter 3 - actions in the narrow corridor

Section 1 - going

Instead of going north in the narrow corridor when the thief is sighted:
	say "There is no way back, physically or metaphorically." instead.
	
Check going nowhere in the narrow corridor:
	say "[oc]

CHECK GOING NOWHERE IN THE NARROW CORRIDOR:
[lb][t2][fls]SAY 'THE ONLY WAY FORWARD IS *SOUTH*.';
[lb][t2][fls]STOP THE ACTION.'

[cc][lb]";
	stop the action.

	
Section 2 - searching

check searching the PWDWindow when the PWDWindow is closed:
	say "(first opening the small sliding window)";
	try opening the PWDWindow.


The can't search unless container or supporter rule does nothing when searching the PWDWindow.

Carry out searching the PWDWindow:
	say "The darkness on the other side beats against the door but leaves no mark. Perhaps this *CRASHING DARKNESS* could prove useful[dot]"
	
After searching the PWDWindow when the thief is tinert:
	say "[lb][ro]

[CAP], THE DARKNESS THAT YOU ONCE FORSOOK WELCOMES YOU BACK. *ASSAY THE CRASHING DARKNESS* BEYOND THE WINDOW AND LEARN ITS SECRETS.

[rc][lb]"
	
Section 3 - opening

The standard report opening rule does nothing when opening the PWDWindow.

Report opening the PWDWindow:
	say "A *CRASHING DARKNESS* spills through the window, roiling over the floor like cold smoke.";
	now the crashing darkness is in the stone hall.
	
Rule for writing a paragraph about the crashing darkness when the pwdwindow is open and the player is in the narrow corridor (this is the darkness spilling through the window rule):
	if the crashing darkness is assayed:
		say "Neither liquid nor gas, the *CRASHING DARKNESS* flows and billows over the floor. You know without feeling that it is cold around your ankles.";
	if the crashing darkness is not assayed:
		say "The *CRASHING DARKNESS*, is neither liquid nor gas, though it flows and billows over the floor. You know without feeling that it is cold around your ankles.[if the crashing darkness is not assayed]

[ro]

[CAP], *ASSAY THE DARKNESS*, THEN MAKE IT YOUR OWN.

[rc][lb]".

instead of closing the pwdwindow:
	say "The window is only as useful as it is open.".
	

	
Section 4 - assaying

check assaying the PWD:
	say "The door, wet as it may be, is not the water." instead.
	
check assaying the PWDWindow:
	say "It is large enough to spill a bit of darkness through." instead.
	
check assaying the dressed stone:
	say "The power that shaped these stones was born of light." instead.
	
carry out assaying the crashing darkness:
	say "[if pwd is not open]It is a source of powerful aphotic magic. *DELUMINE THE DOOR* if you are able.[otherwise]The crashing darkness is a crashing darkness.".
	
Section 5 - gathering

Check gathering the PWD:
	say "Holding light at bay and holding darkness are two different things." instead.
	
Check gathering the PWDWindow:
	say "A window's value lies in what it does and does not permit." instead.
	
Check gathering the dressed stone:
	say "Given the state of the hallway behind you, I suggest you seek power elsewhere." instead.
	
Carry out gathering the crashing darkness:
	say "[one of]You hold out your right hand and feel a current[em]slow at first, but gathering speed[em]pass up your arm and spread throughout your body. It is like and unlike electricity. The power of the *CRASHING DARKNESS* is now yours to use as you wish.[or]Once more, you gather the might of the *CRASHING DARKNESS* unto yourself.[stopping]";
	now the thief is exploding.

[Check gathering the dressed stone]

Section 6 - delumining

collapsing the dressed stone corridor is an action applying to nothing.
collapsing the dressed stone corridor is creating a temporal paradox.

Instead of delumining the dressed stone:
	try collapsing the dressed stone corridor instead.

carry out collapsing the dressed stone corridor:
	say "Concentrating the *CRASHING DARKNESS between your palms, you hurl it at the stones girding this passage through the rock. The long years and recurring seismoses have left this well-wrought structure vulnerable to your powers. As the rockfall approaches you, its roar goes silent, and the stones hang in the air, an irrational curtain of rock
	

[t2]***You Have Failed to Unmake the Past***

[ro]

YOU WILL NOT SO EASILY BE RID OF ME OR YOU, [CAP]. WOULD YOU RECKLESSLY CHANGE THE PAST FROM WHICH THIS WORLD HANGS? YOUR DEATH WILL BE THE DEATH OF MY CHOOSING. THIS GAME IS ABOUT[em]NEVER FOR[em]YOU.

[rc]

The stones suddenly fly upward, forming a ceiling once more, and the strange un-roar of a an avalanche reversed fills your ears. All is just as it was.";
	
carry out delumining the pwd:
	say "A thrilling surge of power wells within you, and your limbs vibrate like wires held taut. You heave the *CRASHING DARKNESS* clear of your frame, sending it crashing into the plain wooden door. Its planks buckle, then explode out and away from you, disintegrating completely.

[ro]

SUCH POWERS ARE THE LEGACY YOU FORSOOK FOR THE SUNLIT LANDS, [CAP].

[rc][lb]";
	now the pwd is open;
	now the thief is tinert;
	now the pwd is busted;
	now the pwdwindow is nowhere.
	
rule for writing a paragraph about the pwd when the pwd is open:
	now the pwd is mentioned.
	
instead of delumining the pwdwindow:
	say "The *CRASHING DARKNESS* is no surgeon. It's force strikes the entire door.";
	try delumining the pwd instead.
	
Chapter 7 - doing anything to pwd

Instead of doing anything to pwd when pwd is open:
	say "You blasted the door out of existence. Nothing remains of it: no splinters, no fixtures, no dust.

[ro]

HOW DOES IT FEEL TO CONFRONT THIS MAN-SIZED ABSENCE? HAVE YOU MET YOUR DOPPLEGANGER?

[rc][lb]".

Book 7 - 0 - backdrops and such in the guardian hallway region

Chapter 2 - the strewn rubble


Chapter 3 - the bracket

the statue bracket is a region.

the statue bracket is in the guardian hallway.

Section 1 - the statues from afar

statuary is a kind of scenery backdrop. the plural of statuary is statuaries. Some statuaries are defined by the table of distant sculpture.

table of distant sculpture
statuary	printed name	destination	disposition	verbiage
headless statue scenery	"headless statue"	bracket	intact	"Off in the distance, you see a headless, ogre-sized warrior carved from a single, massive slab of stone. The figure holds a stone morningstar over its head, ready to strike.[if the real disarmed statue is in near the guardians] It stands facing its armless twin, which stands at the other side of the hall. Together, these stone warriors have kept watch over this passage for at least a score of decades.[otherwise] It stands facing the empty place where its twin once stood[end if].[if the real guardian head is in near the guardians] A large stone head looks up from the rubble at its feet.[end if]"
disarmed statue scenery	"disarmed statue"	bracket	intact	"Down toward the midway point of the hallway, a giant stone human [if the real headless statue is in near the guardians]stands facing its headless twin, which stands at the other side of the hall. The pair seem frozen in the moment immediately before crushing an overmatched opponent.[otherwise]stands facing the empty spot where its opposite number once stood.[end if][if the real guardian arm is in near the guardians] It's right arm lies on the floor in front of it, still clutching a huge bludgeon.[end if]"
guardian head scenery	"guardian head"	bracket	intact	"[if the real headless statue is in near the guardians]A massive stone head, forever estranged from its neck, sneers at the ceiling.[otherwise]The giantic head is all that remains of a large, menacing ogre of stone."
guardian arm scenery	"guardian arm"	bracket	intact	"[if the real disarmed statue is in near the guardians]The arm, which broke away from its owner at the elbow, holds a huge stone morningstar in its hand. Judging by the angles involved, the statue must have been frozen mid-swing.[otherwise]The large stone forearm and hand, along with its even larger spiked mace, is all that remains of a large and fearsome ogre carved from stone."

when play begins:
	repeat through the table of distant sculpture:
		move statuary entry to destination entry;
		now the printed name of the statuary entry is the printed name entry;
		now the description of the statuary entry is the verbiage entry;
		now the indefinite article of the statuary entry is "the".

before printing the name of a statuary:
	say "[indefinite article] "
		
The distant rubble is a scenery backdrop in bracket.

The description of the distant rubble is "[if the real disarmed statue is in near the guardians and the real headless statue is in near the guardians]At the center of this long hallway, two massive stone statues stand guard. They are in poor condition, and the area nearby is strewn with rubble.[otherwise if the real disarmed statue is in near the guardians]Thanks to your efforts, only the one-armed statue remains. It sneers at the newly empty place on the other side of the hallway.[otherwise if the real headless statue is in near the guardians] The headless statue holds a massive weapon aloft, as if waiting to crush any who pass by. As you must know, it faces a recently vacated place on the oppposite wall.[end if][if the real guardian arm is in near the guardians and the real guardian head is in near the guardians] A thick, stone arm clutching a morningstar lies on the ground near a scowling stone head.[otherwise if the real guardian arm is in near the guardians] A thick, stone forearm holding a gigantic stone mace lies among the rubble. [otherwise if real guardian head is in near the guardians] A large stone head sneers upward from its place among the rubble."

Instead of doing anything other than examining to the distant rubble:
	say "The [if number of adversarial stonework in near the guardians is greater than zero]statuary and [end if]rubble is substantial enough to see, but you must approach before acting upon it.".

Chapter 4 - the crashing darkness

rule for writing a paragraph about the crashing darkness when the thief is in the guardian hallway (this is the crashing hallway rule):
	say "The *CRASHING DARKNESS* roils and steams, ankle-deep, over the stone floor. It silently laps against each rising thing: the walls[if the real headless statue is in near the guardians or the real disarmed statue is in near the guardians], the statuary,[end if] and the rubble strewn across this vast hallway."

Book 7 - 1 dungeon entrance

The description of DE is "[first time]Perhaps your display of power was more than the narrow hallway could bear. Just as you pass through the doorway, the ceiling collapses behind you. Neither you nor anyone else will ever pass through there again. [only]This is a long, north-south corridor constructed from rectangular stones cut with mathematical precision. The doorway to the north is a window into a rockfall.

Off to the south, [if the real disarmed statue is in near the guardians and the real headless statue is in near the guardians]two massive, crumbling statues with the broad backs and limbs of ogres stand guard at the hall's midway point. The entire area is strewn with rubble.[otherwise]Some recent demolition work at the hall's midway point has greatly increased the amount of rubble there."

the printed name of de is "Dungeon Entrance"

DE is south of the pwd.
DE is in the bracket..
	
Chapter 1 - nouns in dungeon entrance


[the description of the guardians is "[if the player is in the dungeon entrance]The]

section 2 - crashing darkness redux
	
section 3 - crumbled statue

section 4 - the crumpled mirror box

Chapter 2 - actions in the dungeon entrance

Section 1 - going

Instead of going north in de:
	say "The space beyond the doorway exists only in the past.".
	
Instead of going nowhere in de:
	say "Your future[em]my past[em]lies southward.".
	
Book 8 - Near the Guardians

Near the Guardians is south of the DE.
Near the Guardians is in the guardian hallway.
The description of Near the Guardians is "You stand at the center of a jagged circumference of crumbled stone. Time and earthquakes are co-authors of this disorder.[if the real disarmed statue is in the location and the real headless statue is in the location] Two massive statues stand at either side of the hallway, as if standing guard. They have a dangerous feel despite apparent harmlessnesses.[otherwise if the real headless statue is in the location] The headless statue faces a featureless wall.[otherwise if the real disarmed statue is in the location] The one-armed statue scowls at an empty place on the opposite wall.[end if] [if the real guardian head is in the location and the real guardian arm is in the location]Nearby, a giant human-like head and an arm holding a spiked mace have fallen among the debris.[otherwise if the real guardian head is in the location]A massive stone head looks up from the rubble, sneering at the ceiling.[otherwise if the real guardian arm is in the location]An arm holding a massive, spiked mace lies among the crushed stone on the floor.[end if]"

The B Room is south of Near the Guardians.

Chapter 1 - nouns near the guardians

Section 1 - the real head

The real guardian head is adversarial stonework in near the guardians.
The real guardian head is scenery.
The real head is deluminable.
The printed name of the real head is "massive stone head".
Understand "massive / stone / head" and "giant / ogroid / head" and "guardian / head" as the real guardian head.

The description of the real guardian head is "This giant head sneers at the ceiling, frozen in an expression of inanimate animus.[if the real headless statue is in the location] Its apparent owner stands nearby, holding a stone morningstar aloft[end if].".

instead of doing anything other than touching or wielding aphotic magic or examining to adversarial stoneworks:
	choose row with an anomaly of thief kicking the can in the table of causal anomalies;
	if turns passed entry is greater than zero:
		say "Perhaps it would be best to deal with the [noun] from a distance.";
	otherwise:
		say "The [noun] is sturdy and far too heavy to move. Only magic and earthquakes can affect it.".
		
instead of assaying adversarial stoneworks:
	say "The [noun] takes but never gives.".

Section 2 - the real headless statue

the real headless statue is adversarial stonework in near the guardians.
the real headless statue is scenery.
the real headless statue is deluminable.
the printed name of the real headless statue is "headless stone guardian".
understand "headless / stone / statue" and "headless / stone / guardian" as the real headless statue.

the description of the real headless statue is "[if the real disarmed statue is in the location]The headless statue stands facing its twin on the opposite side of the hall, holding a gigantic stone mace over its shoulder. Despite its apparent immobility, it contributes to the air of malice and danger here.[end if][if the real guardian head is in the location and the real disarmed statue is in the location] The head that once rested upon its shoulders now lies face-up among the rubble, scowling at the ceiling.[otherwise if the real disarmed statue is not in the location] The headless statue stands facing a recently vacated space on the opposite side of the hall, holding a gigantic stone mace over its shoulder. Despite its apparent immobility, it contributes to the air of malice and danger here.[end if]".

Section 3 - the real disarmed statue

the real disarmed statue is adversarial stonework in near the guardians.
the real disarmed statue is scenery.
the real disarmed statue is deluminable.
the printed name of the real disarmed statue is "disarmed stone guardian".
understand "armless / stone / guardian" and "armless / stone / statue" and "disarmed / stone / guardian / statue" as the real disarmed statue.

the description of the real disarmed statue is "Even with its dominant hand missing, it is clear that this dangerous-looking statue was preparing an attack in concert with its [if the real headless statue is not in the location]recently-vanquished [end if]twin across the hallway. It's shoulders are broad and muscular, and sharp canines peak through it's frozen sneer.[if the real guardian arm is in the location] A giant, forearm and hand, once part of the guardian, lies at the statue's feet. It holds a massive spiked bludgeon."

Section 4 - the real guardian arm

the real guardian arm is adversarial stonework in near the guardians.
the real guardian arm is scenery.
the real guardian arm is deluminable.
understand "stone / guardian / forearm / mace / morningstar / arm " as the real guardian arm.
the printed name of the real guardian arm is "stone arm".

the description of the guardian arm is "A muscular forearm and fist clutching a giant sone morningstar lies[if the real disarmed statue is in the location] at the feet of a scowling, one-armed statue[otherwise] before the empty place where the disarmed statue once stood[end if]."

section 5 - the mirror box

rule for choosing notable locale objects for near the guardians:
	set the locale priority of the mirror box to 1;
	set the locale priority of the crashing darkness to 5;

the mirror box is in near the guardians.
the printed name of the mirror box is "crushed wooden box".
understand "crushed / wooden / wood / mirror / box / glass / construction" as the mirror box.

The examine undescribed things rule does nothing when examining the mirror box.
A thing can be examined.

instead of examining the mirror box:
	say "In the space between[if the real disarmed statue is in the location and the real headless statue is in the location] the two menacing statues [otherwise if the real disarmed statue is in the location] the armless statue and the space where the headless stone ogre once stood [otherwise if the real headless statue is in the location] the headless statue and the space where the disarmed statue once stood [otherwise] the spaces once occupied by the two guardian statues[end if], splintered panels of hardwood lie crushed beneath the rubble here. Fragments of mirrored glass lie everywhere, too. [run paragraph on]";
	choose row with an anomaly of being crushed by statuary in the table of causal anomalies;
	if turns passed entry is less than zero:
		say "It seems that, for reasons unclear, a large box covered with mirrored panels was crushed with incredible and sudden force in this spot.";
	otherwise:
		say "The statues must have crushed a large box covered with mirrored panels here in this spot. Presumably, there was someone in it at the time.".
		
Rule for writing a paragraph about the mirror box (this is the hallway mirror box rule):
	choose row with an anomaly of thief being crushed by statuary in the table of causal anomalies;
	if turns passed entry is greater than zero:
		say "This collapsed box of wood and glass was presumably crushed by the statues here. The pulverized and dessicated remains of some human must be folded within.";
	otherwise:
		say "A large, wooden box lies flattened beneath the rubble here. Bits of mirrored glass are scattered about, some yet clinging to the wood. It rests at the exact midway point between [if the real headless statue is in the location and the real disarmed statue is in the location]the two statues[otherwise if the real headless statue is nowhere and the real disarmed statue is nowhere]the place where the statues once were[otherwise]the place where the statues either stand or stood[end if].".

After examining the mirror box:
	now the mirror box is examined.
	
instead of doing anything other than wielding aphotic magic or examining to the mirror box:
	choose row with an anomaly of thief being crushed by statuary in the table of causal anomalies;
	if turns passed entry is greater than zero:
		say "The box is someone's flattened tomb. Leave the dead be.";
	otherwise:
		say "It isn't yet clear what the box is. You should investigate further.".
	
[the hallway mirror box rule is listed before the crashing hallway rule in the for writing a paragraph about rulebook.]

Chapter 2 - actions in near the guardians

section 1 - going south and getting flattened

instead of going south from near the guardians when number of adversarial stoneworks in the location is greater than zero:
	say "The statuary is unnerving, but [if the number of adversarial stoneworks in the location is less than four]you have taken precautions[otherwise]the statues are dead and still[end if]. Slowly, you make your way through the rubble. An anticipation creeps over you: is that the groan of flexing rock?[run paragraph on][if the real guardian head is in the location] The stone eyes in the stone head lying on the stone floor[em]did they roll toward you?[run paragraph on][end if][if the real guardian arm is in the location]  Perhaps the severed arm holding the gigantic stone morningstar twitched![run paragraph on][end if]

Just as you take another step further,[if the real guardian head is in the location] the severed head on the ground roars, rolling to face you on its side![otherwise if the real disarmed statue is in the location] the disarmed statue turns toward you with a deafening roar![otherwise if the real headless statue is in the location] the headless statue turns toward you, raising its mace above its head![otherwise] The lone arm on the ground wobbles, then rights itself, standing upright on its 'elbow'. The tip of its weapon looms overhead; it is at least six feet long.[end if][lb]";
	if the number of adversarial stoneworks in the location is four:
		say "The hallway comes to life. The two statues prepare to crush you: one with its weapon, the other with its fist. Beside you, the severed head springs into the air, mouth wide open. The severed stone arm rears back like a jointed serpent, morningstar held high. It is almost too much to keep track of, but who could reasonably expect that of you?";
	otherwise if the number of adversarial stoneworks in the location is three:
		if the real disarmed statue is in the location and the real headless statue is in the location:
			if the real guardian head is in the location:
				say "The hallway comes to life. The two statues prepare to crush you: one with its weapon. the other with its fist. Beside you, the severed head springs into the air, mouth wide open. It is almost too much to keep track of, but who could reasonably expect that of you?";
			otherwise if the real guardian arm is in the location:
				say "The hallway comes to life. The two statues prepare to crush you: one with its weapon. the other with its fist. The severed stone arm rears back like a jointed serpent, morningstar held high. It is almost too much to keep track of, but who could reasonably expect that of you?";
			otherwise if the real headless statue is in the location:
				say "The headless statue turns toward you, mace held high. At your left, the severed head springs into the air, mouth wide open. The arm, the statue, and the head all move to strike in concert. Whatever science or magic coordinates their actions is beyond the skill of even the Accardi Guildmaster. I'm impressed that you would make that comparison now, in this attention-consuming moment.";
			otherwise if the real disarmed statue is in the location:
				say "The disarmed statue turns toward you, fist held high. At your left, the severed head springs into the air, mouth wide open. The arm, the statue, and the head all move to strike in concert. Whatever science or magic coordinates their actions is beyond the skill of even the Accardi Guildmaster. Honestly, I'm impressed that you would make that comparison now, in this attention-consuming moment.";
	otherwise if the number of adversarial stoneworks in the location is two:
		if the real guardian arm is in the location and the real guardian head is in the location:
			say "While you must have had some foretaste of danger, your precautions were less than thorough. Perhaps you are surprised to know that the head and arm are more than capable of taking you apart. They rise up, as if one, and lurch in your direction. Well? Are you surpised?";
		otherwise if the real headless statue is in the location and the real disarmed statue is in the location:
			say "Acting in concert, the statues crush you in a single movement: a fist one one side, a morningstar on the other. Looking on the bright side, it is over before the pain can register[em]a virtue among unpleasantnesses, to be sure.";
		otherwise:
			say "The [list of adversarial stonework in the location] are more than up to the task of taking you apart, and they do. The remaining statue raises its [if the real disarmed statue is in the location]fist high above your head[otherwise if the real headless statue is in the location]weapon high above your head[end if] while the [if the real guardian head is in the location]stone head springs toward you, fangs bared[otherwise]forearm hops toward you on its elbow, mace readied[end if].";
	otherwise if the number of adversarial stoneworks in the location is one:
		if the real headless statue is in the location:
			say "The massive headless statue. which has somehow escaped your experiments, reacts to your proximity by crushing you underneath its gigantic, stone morningstar.";
		otherwise if the real disarmed statue is in the location:
			say "The massive disarmed statue, which has somehow escaped your experiments, reacts to your proximity by crushing you underneath its gigantic, stone fist.";
		otherwise if the real guardian arm is in the location:
			say "Perhaps you think you have been sufficiently thorough. Imagine your surprise when the muscular stone forearm, stone mace in hand, rears up on its elbow, before bringing the giant weapon down on your head.";
		otherwise if the real guardian head is in the location:
			say "Perhaps you think you have been sufficiently thorough. Imagine your surprise when the giant stone head rights itself before springing toward you, fangs bared.";
	try being crushed by statuary;
	
being crushed by statuary is an action applying to nothing.
being crushed by statuary is creating a temporal paradox.

carry out being crushed by statuary:
	say "Now you know what happened to the mirrored


[t2]***You Have Failed to Unmake the Past***


[ro]

[CAP], YOU HAVE NO SAY IN THIS STORY'S ENDING. HERE, IN MY PLACE OF POWER, I CHOOSE EVERY OUTCOME. YOU HAVE TOLD ME WHAT I HAVE SEEN AND HEARD FOR THE LAST TIME.

[rc]

stand among the crumbing stonework once more.".

Section 2 - going

Carry out going south from near the guardians:
	say "You avoid stepping on the remains of the mirrored box, just as you would avoid walking on any other grave.[first time]

Just south of the crushed box, an ornate compass rose is carved in the floor. A broken wooden pole juts from a hole in its center. Perhaps it once had something to do with the mirrored box? The hole, like the rest of this complex, is the lair of a single, outlived purpose.

Walking past it, you soon reach...[only]"

getting past the guardians is an action applying to nothing

Last report going south from near the guardians:
	try getting past the guardians.
	
check going nowhere in near the guardians:
	say "[OC]

CHECK GOING NOWHERE IN NEAR THE GUARDIANS:
[F2]SAY 'WHILE YOU CAN RETURN *NORTH*, YOUR DESTINY LIES TO THE *SOUTH*;
[F2]STOP THE ACTION.'.

[CC][LB]";
	stop the action.
	
Section three - touching

instead of touching adversarial stonework:
	say "The stone has been polished smooth and is warmer than you might expect."
	
Section four - moving
	
	
Section five - talking

Section six - delumining

Carry out delumining the real head:
	say "The power of darkness itself springs forth from your hand, crushing the giant, scowling head into something less than dust. The broad incisor behind its lip twitches on its way to nowhere and nothing.";
	now the real head is nowhere;
	now the guardian head scenery is nowhere;
	now the thief is tinert.
	
Carry out delumining the real headless statue:
	say "With a gesture, you send the darkness crashing against the stone. It quivers, contracts, then disappears in a murk.";
	now the real headless statue is nowhere;
	now the headless statue scenery is nowhere;
	now the thief is tinert.
	
Carry out delumining the real disarmed statue:
	say "Concentrating, you direct waves of darkness forward, breaking against the giant, armless statue. It shivers, mouth open, before vanishing on the still air.";
	now the real disarmed statue is nowhere;
	now the disarmed statue scenery is nowhere;
	now the thief is tinert.
	
Carry out delumining the real guardian arm:
	say "You point, calling forth the darkness. The arm, mace in hand, wobbles as if trying to right itself, but it is too soon gone in a cloud of delumined dust.";
	now the real guardian arm is nowhere;
	now the guardian arm scenery is nowhere;
	now the thief is tinert.
	
Carry out delumining the mirror box:
	choose row with an anomaly of thief being crushed by statuary in the table of causal anomalies;
	if turns passed entry is greater than zero:
		say "Someone died in there. Let's not wake them.";
	otherwise:
		say "The box has seen enough already.".
		

		
AFTER DELUMINING AN ADVERSARIAL STONEWORK FOR THE FIRST TIME:
	SAY "[ro]

AS LONG AS YOU STAND IN THE PRESENCE OF APHOTIC MAGIC, YOU CAN DELUMINE OBJECTS WITHOUT FIRST IT UNTO YOU. FOR INSTANCE, HERE YOU MAY TYPE *DL THE DRESSED STONE* AND IT WILL BE AS YOU WILL IT.

SUCH IS THE POWER OF YOUR PEOPLE, WHOM YOUR IMPERIAL MASTERS FORCED FROM THEIR HOMES.

[rc][lb]".
	
section 7 - assaying

carry out assaying the mirror box:
	say "Dark, but not your kind of dark.".
	
Book 9 - The Beam Room

The b room is in the statue bracket.
The printed name of the b room is "Beam Room".
The description of the b room is "With the Guardians of Zork forever gone, this is the southern half of a newly-vacated corridor of dressed stone. You can continue to the south.

[first time]Though... this location does feature one curiosity. [only]A narrow red beam is directed across this space, east-to-west, an inch above the floor.[if the can is in the location] At present, the beam is blocked by an aerosol can of some sort[otherwise] Even though the beam is no longer blocked, its function remains unclear."

Chapter 1 - Nouns in the Beam Room

The beam is in the b room.
The printed name of the beam is "narrow red beam".
The beam is deluminable.
Understand "narrow / red / beam" as the beam.
The beam is scenery.
The description of the beam is "This narrow bit of light, wide as yarn pulled taut, [if the can is not in the location]crosses the room. Since their are no visible sensors or projectors visible in the walls, it's make and purpose are unknown[otherwise]emerges from the eastern wall. It is interrupted by an aerosol can resting on the floor[end if].".

Chapter 2 - The Can

The can is in the b room.
the can is deluminable.
The printed name of the can is "[if can is unexamined]aerosol can[otherwise]can of Frobozz Magic Grue Repellant (empty)".


The description of the can is "'!!! FROBOZZ MAGIC GRUE REPELLENT !!!

Instructions for use: Apply liberally to creature to be protected. Duration of effect is unpredictable. Use only in place of death!

(No warranty expressed or implied)'

[oref]

Dave Lebling and Marc Blank, Zork III. Cambridge, Infocom, 1982

[cref]

The can is empty."

Rule for writing a paragraph about the can:
	now the can is mentioned.

Chapter 2 - actions in the beam room

section 1 - general


the standard report taking rule does nothing when taking the can.

Carry out taking the can:
	Say "the beam of light, no longer interrupted, bisects the entire hall. A click can be heard to the north, though there is no visible movement to report.[first time]

[ro]

THE BEAM WAS A PROBLEM BESTED, YEARS AGO, BY YOUR KILLER.

[rc][lb][only]".
	
Section 3 - delumining in the beam room

Carry out delumining something carried by the player when the player is exploding:
	now nString is the printed name of the noun;
	try kicking the can.

Carry out delumining the beam when the player is exploding:
	say "You club the light with a hammer.";
	now the player is tinert.
	
Carry out delumining the can when the can is not carried by the player:
	say "The can explodes with a loud yet ineffectual pop.";
	now the can is nowhere;
	now the player is tinert;

		
kicking the can is an action applying to nothing.
kicking the can is creating a temporal paradox.

carry out kicking the can:
	say "It's like swatting a fly with a statue of the Emperor. The broad force of the *CRASHING DARKNESS* strikes the [nString] in your hand, rendering the air around you wet and red wi


[t2]***You Have Failed to Unmake the Past***[pb]

[ro]

YOU WILL NOT ESCAPE YOUR PAST, [CAP].

[rc]

The red, bloody spray flies backward, into your elbow as your forearm is called back from oblivion. You have failed, once again, to break free of the Demiurge's power.".

instead of doing anything other than taking or dropping or wielding aphotic magic or inserting something into or examining when the current action involves the can:
	say "[oc]

INSTEAD OF DOING ANYTHING OTHER THAN TAKING OR DROPPING OR EXAMINING OR WIELDING APHOTIC MAGIC OR INSERTING SOMETHING INTO WHEN THE CURRENT ACTION INVOLVES THE CAN:
[lb][t2][fls]SAY 'THE CAN HAS NO APPARENT USE.'

[cc]".

Section 3 - touching in the beam room

the report touching things rule does nothing when touching the beam.

carry out touching the beam:
	say "You crouch near the beam, then wave your hand in and out of it. It looks like something should happen, [if the can is in the location]but the can is indifferent to the beam's absence[otherwise]and, though you do hear a clicking to the north, nothing interesting happens there or anywhere else[end if]."
	
instead of doing anything other than touching or wielding aphotic magic to the beam:
	try touching the beam.
	
instead of wielding aphotic magic when the current action involves the beam:
	say "The beam is made of light, and you are made of not-light. Its power is not yours.".
	
Section 4 - dropping the can

	
Section 5 - assaying in the beam room

Carry out assaying the beam:
	say "Like all light, the beam resists aphotic power. Its origins appear to be purely scientific, with no magical implications whatsoever.".
	
Carry out assaying the can:
	say "While it is likely that magic was once used to fill the can, its design and construction owe everything to engineering, not aphotic magic."
	
section 6 - going

check going nowhere in the b room:
	say "[OC]

CHECK GOING NOWHERE IN THE BEAM ROOM:
[F2]SAY 'THE WAY CONTINUES *SOUTH*, THOUGH IT IS POSSIBLE TO RETREAT *NORTH*.';
[F2]STOP THE ACTION.

[CC]";
	stop the action.
	
Book 10 - the button room

btn rm is south of the b room.
the printed name of btn rm is "Button Room".

The description of the btn rm is "This is the southern end of a long, high, and wide hall. A narrow, red beam bisects the hallway to the immediate *NORTH*, and a stairway leads *SOUTH* and *UP*. Several extinguished torches are mounted along each wall.[if the mounted torches are delumined] There is a gap where you bashed the wall with *CRASHING DARKNESS*.[end if]

A red button is embedded at eye level in the western wall."

structural integrity of the button room is a number that varies.
structural integrity of the button room is two.

Chapter 1 - nouns in the btn rm

Section 1 - the torch(es)

the torch is in btn rm.
The description of the torch is "Arm-length, pitch-covered.".

rule for writing a paragraph about the torch when the player is in btn rm:
	say "One torch lies on the floor, having left the comfort of its peers.".
	
instead of doing anything other than wielding aphotic magic or examining or taking or dropping to the torch:
	say "[oc]

INSTEAD OF DOING ANYTHING OTHER THAN WIELDING APHOTIC MAGIC OR EXAMINING OR TAKING OR DROPPING TO THE TORCH:
[lb][t2][fls]SAY 'THE TORCH, IF LIT, WOULD LIKELY HARM YOU AFTER A MOMENT OR TWO. PERHAPS YOU SHOULD LEAVE IT BE FOR NOW.'

[cc][lb]"

Section 2 - the button

The red button is in the btn rm.
The printed name of the red button is "red button".
The description of the red button is "This red button, like all red buttons, invites[em]demands[em]pressing.".
rule for writing a paragraph about the red button:
	now the red button is mentioned.

rule for deciding whether all includes the red button:
	it does not.

instead of doing anything other than pushing or delumining or examining to the red button:
	say "[if the red button is delumined]The button has left its button days behind[otherwise]A button is only as good as its last press.".

Section 3 - the stairs

The short stairs are in the btn rm.
The short stairs are scenery.
The description of the short stairs is "The stairs are narrow, steep, and lead up to an open doorway.".
Instead of climbing the short stairs:
	try going south.
Instead of going up in btn rm:
	try going south.
	
instead of doing anything other than climbing or examining to the short stairs:
	say "[oc]

INSTEAD OF DOING ANYTHING OTHER THAN CLIMBING OR EXAMINING THE SHORT STAIRS:
[lb][t2][fls]SAY 'THEY ARE ONLY GOOD FOR CLIMBING.'

[cc][lb]"

Section 4 - the engravings door

The engDoor is a door.
The engDoor is open.
The engDoor is south of the btn rm.
The engDoor is north of the Engravings Room.
the engDoor is open.
the engDoor can be blasted. the engDoor is not blasted.
the engDoor is scenery.

understand " secret / door / unadorned /wood / wooden" as the engDoor.

The printed name of the engDoor is "[if the thief is in the btn rm]door at the top of the stairs[otherwise]collapsed doorway".

The description of the engDoor is "[if the engdoor is not delumined]The door, at least on this side, appears to be made of unadorned wood. It stands wide open[otherwise]The previous tenant of the collapsed doorway is nowhere to be found[end if].".

section 5 - the mounted torches

[zork]

the mounted torches are in the btn rm.
the mounted torches are a plural-named thing.
the mounted torches are scenery.
understand "mounted / torches" as the mounted torches.
does the player mean doing something to the mounted torches: it is unlikely.
the description of the mounted torches is "Most of this area was once lit from indirect, magical sources. These torches likely served a dramatic effect.[if the mounted torches are delumined] There is a break in the line where you delumined part of the wall.[end if]".

instead of doing anything other than examining or wielding aphotic magic to the mounted torches:
	say "The torches and their light are out of reach, fortunately." .

Chapter 2 - actions in the btn rm

section 1 - opening and closing

Instead of opening the engDoor in btn rm:
	say "The door stands wide open already.";

Instead of closing the engDoor in btn rm:
	say "The door is held open by a hidden mechanism. You cannot budge it with the strength of your limbs.".
	
section  2 - examining

[deprecated]

section 3 - pushing the button

the red button can be depressed. the red button is not depressed.

instead of pushing the red button when the red button is delumined:
	say "Is a button that can't be pushed a button?"

Carry out pushing the red button:
	if the red button is depressed:
		say "the button is flush with the panel it is installed in, and cannot be pushed further.";
	otherwise:
		now the red button is depressed;
		say "You hear a click to the north, but nothing else happens.[first time]

[ro]

[CAP], YOUR KILLER WILL SOLVE THE RIDDLE OF THE BUTTON AND THE BEAM DECADES AGO. IT IS ONLY HERE NOW BECAUSE IT WAS HERE THEN.

[rc][lb][only]"
		
Before doing something in the btn rm when the red button is depressed:
	if the current action is going somewhere:
		say "As you leave, you hear the button pop back to its original position.";
	otherwise:
		say "The button pops back into its orginal position.";
	now the red button is not depressed.

section 4 - going

check going nowhere in the btn rm:
	say "[OC]

CHECK GOING NOWHERE IN THE BTN RM:
[F2]SAY 'THE WAY BACK IS *NORTH*, BUT YOUR FATE LIES *SOUTH* AND *UP*.';
[F2]STOP THE ACTION.'

[CC][LB]."

before going south from btn rm:
	say "You make your way up the short flight of stairs.".
	
section 5 - delumining 
		
carry out delumining the torch when the torch is in the btn rm and the player is exploding:
	say "You crush the torch and the floor surrounding it. The hall shakes ominously. It wouldn't take much to bring the ceiling down.

[ro]

SUCH CONFIDENCE, DESTROYING A TORCH DURING THE COURSE OF AN ADVENTURE.

[rc][lb]";
	if the structural integrity of the button room is not 99:
		decrement the structural integrity of the button room;
	now the player is tinert;
	now the torch is nowhere.
	
carry out delumining the mounted torches when the mounted torches are not delumined:
	say "You manage to strike three in one blow. The hall replies with a substantial tremor.";
	if the structural integrity of the button room is not 99:
		decrement the structural integrity of the button room;
	now the player is tinert;
	
carry out delumining the mounted torches when the mounted torches are delumined:
	say "

[ro]

NO, [CAP]. I AM NOT PERFORMING FOR YOUR AMUSEMENT. YOU ARE PERFORMING FOR ME. DO A NEW THING, OR DO NOTHING.

[rc][lb]"

Check delumining the red button when the player is exploding:
	if the button is delumined:
		say "Again? You begin to bore me, [lct]." instead.

Carry out delumining the red button when the player is exploding:
	say "A dragon biting a shrew. The button is now permanently recessed. It has done nothing for the last time.

The ceiling rumbles.";
	if the structural integrity of the button room is not 99:
		decrement the structural integrity of the button room;
	now the thief is tinert.
	
Check delumining the engDoor when the player is exploding and the engDoor is delumined:
	say "You can only destroy something once." instead.
		
Carry out delumining the engDoor when the player is exploding and the player is in btn rm:
	say "You blast the door out of existence, leaving a door-shaped hole in the wall.

The stone overhead shakes, scattering dust everywhere.";
	if the structural integrity of the button room is not 99:
		decrement the structural integrity of the button room;
	now the description of the engDoor is "[if the player is in the btn rm]There is a jagged opening where the door at the top of the stairs once stood[otherwise]The doorway leading south and down has collapsed. It is filled with jagged pieces of the ceiling.[end if].";
	now the engdoor is busted;
	now the player is tinert.

Instead of doing anything other than delumining or examining or assaying to the engDoor when the engDoor is delumined:
	if the player is in the btn rm:
		say "If a hole is a door, then what is a door?" instead;
		
section 6 - assaying

carry out assaying the torch:
	say "If lit, the torch will damage you and your magic. You can get no power from it."
	
carry out assaying the mounted torches:
	say "Be glad their light is not nearer or stronger.".
	
section 7 - general

last report going south from near the guardians for the first time:
	say "[ro]

[CAP], OTHER GODLINGS AND THEIR PROPHETS CLAIM THAT EVERY CREATED THING AND PLACE MUST SERVE A PURPOSE. WHAT IF SOMETHING IS ONLY HERE SO THAT YOU CAN BE ITS WITNESS? EVERYTHING HERE, I BUILT FOR YOU.

BUT YOU, I BUILT FOR ME.

[rc][lb]"
	
Chapter 3 - destroying the beam room
	
Section 6 - raising a ruckus

raising a ruckus is an action applying to nothing.
raising a ruckus is creating a temporal paradox.

After doing something in the btn rm when the structural integrity of the button room is zero:
	try raising a ruckus instead.
	
Carry out raising a ruckus:
	say "Your experimentation has gone one rumble too far. First, you are showered in dust. The large blocks of stone from which this passage is made then fall, practically all at once. You wince in anticipation, but only silence follows. The stones are all suspended overhead, just inches


[t2]***You Have Failed to Unmake the Past***[pb]

[ro]

YOUR DATE WITH YOUR KILLER WILL NOT BE MISSED, NOT EVEN FOR THE END OF THE WORLD.

[rc]

fall upward, fitting perfectly into their previous homes, mortar once more sealing them in place.";
	now structural integrity of the button room is 99;
	now the player is exploding.

Book 11 - 0 - Regarding the greater earthquake territory

Every turn when the player is in the greater earthquake territory and the player is not a time traveller (this is the ambient future rule):
	if a random chance of one in six succeeds:
		say "[one of]The floor trembles under your feet[or]Somewhere far off, you hear the crash of stone crushing stone[or]The ground shakes briefly[or]You hear another loud report[or]Everything around you shakes violently. You brace yourself for falling stones, but none come[or]Not even the ambivalent cold-bloodedness can take the edge of the constant shaking here[or]It is only a matter of time before this entire complex falls in[cycling].".

Book 11 - the engravings room

Chapter 1 - Various Rules

before going south from the btn rm:
	say "[if the engDoor is delumined]With a loud and sudden crash, the button room and its corresponding stair collapse, instantly filling the opening in the north wall with fallen rock[otherwise]With a loud and sudden crash, the open door in the north wall vanishes under a heap of fallen rock[end if].";
	now the engDoor is busted.

Chapter 2 - Descriptions and Definitions

The engravings room is northeast of the Damp Passage.
The engravings room is northwest of the Dead End.
The printed name of the engravings room is "Engravings Room".

The description of the Engravings Room is "This is another man-made space dressed in cut stone. In the north wall, a collapsed doorway is framed by a stone wall completely covered with engraved characters and figures.

This room once had exits to the *SOUTHWEST* and *SOUTHEAST*, though the southeast passage seems recently collapsed."

Chapter 3 - nouns in the Engravings Room

Section 1 - the engravings

the engraved wall are in the engravings room.
the printed name of the engraved wall is "engravings".
understand "engraving / engravings / north / wall / stone" as the engraved wall.
the engraved wall is a plural-named thing.
the engraved wall is scenery.
does the player mean doing something to the engraved wall:
	it is likely.

the description of the engraved wall is "The wall is completely covered in depictions of three characters performing various deeds in underground settings. There is a robed figure resembling the ancient engineer in the treasury. Elsewhere, a man holding a brass lantern examines a wall of stone carvings.

At center-left, a familiar-looking man in a hooded cloak holds a jeweled egg in his left palm. The egg is open, revealing a clockwork bird.[first time]

Were you still alive, the sight would break you into a sweat.[only]"

Section 1 - more on the door

The collapsed doorway is in the engravings room.
The collapsed doorway is scenery.
understand "door / engraved / secret / unadorned / wood / wooden" as the collapsed doorway.
Instead of doing anything to the engDoor when the player is in the engravings room:
	now the noun is the collapsed doorway.

Instead of doing anything other than assaying or examining or gathering or delumining when the current action involves the collapsed doorway:
	say "[lb][oc]

Instead of doing anything other than assaying or delumining when the current action involves the collapsed doorway:
[lb][t2][fls]say 'The door is gone, and you cannot act upon its memory.'

[cc][lb]"
	
does the player mean doing something to the engDoor when the player is in the engravings room:
	it is very unlikely.
	
the description of the collapsed doorway is "Is it luck that you were not there when the ceiling fell? There are many kinds of luck.".

Carry out delumining the collapsed doorway:
	say "You destroy a substantial amount of rock, which is quickly replaced.";
	now the player is tinert.

Section 2 - the collapsed passage

the collapsed passageway is in the engravings room.
the collapsed passageway is scenery.
understand "collapsed / passageway" and "collapsed / passage" as the collapsed passageway.
does the player mean doing something to the collapsed passageway:
	it is unlikely.
	
the description of the collapsed passageway is "A departed possibility.".
instead of examining southeast in the engravings room:
	try examining the collapsed passageway.
instead of going southeast from the engravings room:
	try examining the collapsed passageway.
instead of examining southeast in engravings room:
	try examining the collapsed passageway.
instead of doing anything when the current action involves the collapsed passageway:
	say "A departed possibility.".
	
instead of delumining the collapsed passageway:
	try delumining the collapsed doorway instead.
	
instead of going north in the engravings room:
	try touching the collapsed doorway.
	
Chapter 4 - actions in the engravings room

Section 1 - touching

carry out touching the engraved wall:
	say "Though you are insensitive to heat, you know that they are cool to the touch. The work is very fine, with smooth lines and curved surfaces.".
	
Section 2 - assaying

carry out assaying the engraved wall:
	say "This work predates the rise of the Empire. Who knows what powers shaped it?".
	
carry out assaying the collapsed doorway:
	say "While some events add to the world's darkness, not all of them are of the darkness.".
	
carry out assaying the collapsed passageway:
	say "[one of][ro]

THE MAGIC HOLDING THIS COMPLEX TOGETHER, WILL SOON BE AS DEAD AS YOU ARE. THE CAVE-INS ARE A CAUTION, [CAP], NOT AN OPPORTUNITY.

[rc][lb][or]Whatever secrets the passage might guard are safely buried.[stopping]"

SECTION 3 - GOING

check going nowhere in the engravings room:
	say "[OC]

CHECK GOING NOWHERE IN THE ENGRAVINGS ROOM:
[F2]SAY '*SOUTHWEST* IS THE ONLY WAY FORWARD.';
[F2]STOP THE ACTION.

[CC][LB]";
	stop the action.

section 4 - delumining

instead of delumining the engravings:
	say "[if the engravings are examined]Is that you there, holding the egg? You should leave it be.[otherwise]Try taking a look at it first.".

Book 12 - Damp Passage

Chapter 1 - placeholder for rules

Chapter 2 - description

Damp Passage is southwest of engravings room.
Damp Passage is in greater earthquake territory.
the description of damp passage is "The stone underfoot is damp and covered with moss in places. To the south, an ancient spillway of some sort ascends from a narrow channel in the floor. The channel disappears into a rockfall in the northern wall. An eastern passage is likewise collapsed.".

Chapter 3 - nouns in the damp passage

Section 1 - the seeping darkness

the seeping darkness is in the damp passage.
the seeping darkness is aphotic.
the description of the seeping darkness is "The seeping darkness has no physical properties. It is merely a hole in the world. Try to *ASSAY THE SEEPING DARKNESS* instead."

rule for writing a paragraph about the seeping darkness:
	say "A *SEEPING DARKNESS* gathers in the low places of the room: a wet fog of darkness, a dampness."

Section 2 - the channel

the channel is in the damp passage.
the channel is scenery.
the printed name of the channel is "slippery channel".
understand "/ slippery / spillway / channel" as the channel.
the description of the channel is "This channel was obviously part of some sort of water transport system built by colonizers during the reign of Duncanthrax. It is slick and damp to the point of impassability, but the rubble near the north wall offers safe passage.".

Section 3 - the moss

the moss is in the damp passage.
the moss is scenery.
the description of the moss is "Cave moss thrives in the wet dark here, especially in the channel bisecting the room here."

Section 4 - stone

the damp stone is in the damp passage.
the damp stone is scenery.
the description of the damp stone is "Like the other constructed areas here, the stone is well-fitted and precisely cut. The dampness in this space has granted moss purchase in its cracks and on its surfaces.".

Section 5 - the spillway

the spillway is in the damp passage.
the spillway is scenery.
the description of the spillway is "Like the channel at its bottom, the spillway is slick with damp moss.".

Section 6 - the rockfall

the rockfall is in the damp passage.
the rockfall is scenery.
the description of the rockfall is "Stones of varied sizes block the channel to the north. What's one more place you cannot go?".

instead of examining north:
	try examining the rockfall instead.

Section 7 - the eastern passage

the eastern passage is in the damp passage.
the eastern passage is scenery.
the description of the eastern passage is "Who knows what wonders hide there?".

instead of examining east:
	try examining the eastern passage instead.

Chapter 4 - actions in the damp passage

section 1 - assaying in the damp passage

carry out assaying the seeping darkness:
	say "The *SEEPING DARKNESS* rolls over the ground like wet fog.".
	
section 2 - delumining in the damp passage

carry out delumining something in damp passage when the player is damp:
	say "Concentrating, you coat the [noun] with the *SEEPING DARKNESS*. Presumably, were it dry, it would now be damp. But it isn't.";
	now the player is tinert.

instead of delumining something in damp passage when the player is exploding:
	say "[oc]

instead of delumining something in damp passage when the player is exploding:
[lb][t2][fls]try being wet instead.

[cc]";
	try being wet instead.
	
section 3 - gathering in the damp passage

carry out gathering the seeping darkness:
	now the player is damp;
	say "[one of]You pull the power of the *SEEPING DARKNESS* into yourself.[or]once again, you draw the power of the *SEEPING DARKNESS* unto yourself.[stopping]".
	
	
Section 3 - being wet

being wet is an action applying to nothing.
being wet is creating a temporal paradox.
carry out being wet:
	say "Your antics are more than the northern wall can bear. It shivers, then rumbles, then falls forward, seemingly pulling the ceiling down with it. Just as the stones reach you, they freeze, hanging motionless in place. An alien quiet


[t2]***You Have Failed to Unmake the Past***[pb]

[ro]

[CAP], I MADE THIS WORLD, AND ONLY I CAN UNMAKE YOU. HOW LONG WILL YOU STRUGGLE?

[rc][lb]

damp passage. All is as it was before.".

section 4 - going

instead of going north in damp passage:
	say "As impassable as the door to death's kingdom.".
	
instead of going south in damp passage:
	say "Not even the dexterity of an imperial spymaster can best that incline.".
	
check going nowhere in damp passage:
	say "[OC]

CHECK GOING NOWHERE IN THE DAMP PASSAGE:
[F2]SAY 'THE WAY WIDENS TO THE *WEST*, WHILE THE ENGRAVINGS ROOM LIES *NORTHEAST* OF HERE.';
[F2]STOP THE ACTION.

[CC][LB]";
	stop the action.

Book 13 - The Junction 

Chapter 1 - rules and whatnot



Chapter 2 - description and definitions

Junction is west of damp passage.
The printed name of junction is "Junction".
Junction is in greater earthquake territory.

The description of junction is "A crossroads. To the *NORTH* a broad stairway climbs into darkness. A path widens to the *WEST*, while a damp stone corridor leads *EAST*. The way *SOUTH* is narrow and cramped.

At the center of the room:[if the sack is not carried by the player] an alien familiar sack laid over a spent rock. It belongs to you, somehow.[otherwise] a bare, spent rock.".

Chapter 3 - nouns in junction

Section 1 - stairway

the distant stairway is in junction.
the distant stairway is scenery.

the description of the distant stairway is "Off to the north, rising into dark beyond reckoning."

instead of doing anything other than examining to the distant stairway:
	say "From here, a sight, a hair above an idea.".
	
Section 2 - the rock

the great rock is in junction.
the great rock is a scenery supporter.
the description of the great rock is "A stone fit for a sword.[if the sack is carried by the player] In fact, a slot in its upper surface may have once contained one.[end if] It is waist high, broad, and approximately square, and unshaped by masons.".
understand "bare / spent /rock / great" as the great rock.

[Rule for printing room description details of the sack:
	say "An alien familiar sack laid over a spent rock. It belongs to you, somehow." instead.]
	
Rule for printing room description details of the great rock: omit contents in listing.

the describe what's on scenery supporters in room descriptions rule does nothing when the player is in junction.

Instead of doing anything other than examining to the great rock:
	say "[ro]

[CAP], THE STONE KNOWS ONLY PRACTICAL MEN, LIKE YET UNLIKE YOU.

[rc][lb]".

Section 3 - the sack

the sack is on the great rock.
the description of the sack is "[if the sack is not carried by the player]A dirty canvas and leather sack. Unrotted, though made of stuff that rots.[otherwise]The sack is filthy, but well-stitched. A strange forever lies inside.".
the sack is the player's holdall.
the sack is precious.

rearranged belongings is a truth state that varies.

before going somewhere in junction when sack is on the great rock:
	say "The sack draped across the rock belongs to you. You pick it up on your way out, slinging it over your left shoulder.";
	now the sack is carried by the player;
	repeat with item running through things carried by the player:
		if item is not nothing:
			if item is not precious:
				now item is in the sack.
				
every turn when the sack is carried by the thief (this is the sack loading rule):
	now rearranged belongings is false;
	repeat with item running through things carried by the player:
		if item is not nothing:
			if item is not precious:
				now item is in the sack;
				now rearranged belongings is true;
	if rearranged belongings is true:
		say "You rearrange your belongings.".
		
Instead of closing the sack:
	say "No. You may need to access its contents quickly.".
	
carry out assaying the sack:
	say "The sack is magical, and bigger than it looks."

Section 4 - the slot

the slot is part of the great rock.
the slot is a container.
the slot is scenery.

instead of doing anything when the current action involves the slot:
	say "[oc]

INSTEAD OF DOING ANYTHING WHEN THE CURRENT ACTION INVOLVES THE SLOT:
[F2]SAY 'THE SLOT AND ITS CONTENTS (WILL) EXIST(ED) ONLY TO SERVE YOUR KILLER.'.

[cc][lb]"

Chapter 4 - actions in junction

section 1 - taking 

carry out taking the sack:
	say "The sack has a rightness in the hand and over the shoulder. It was meant and made for you.".
	
The standard report taking rule does nothing when the noun is the sack.

section 2 - dropping
 
instead of dropping the sack:
	say "[oc]

instead of dropping the sack:
[lb][t2][fls]say '[bk]one of[cb]The sack, falling from your grasp, falls into your grasp[dot][bk]or[cb]You cannot bring yourself to give it up[dot][bk]or[cb]The big nothing inside the sack will not release you[dot][bk]or[cb]What is a thief without a sack[q][bk]purely at random[cb]'

[cc][vls]

What is a thief without a sack?"

section 3 - going

check going nowhere in junction:
	say "[OC]

CHECK GOING NOWHERE IN JUNCTION:
[F2]SAY 'THIS IS AN OPEN AREA WHERE TWO PASSAGES INTERSECT. ONE *NORTH*-*SOUTH*, AND THE OTHER *EAST-WEST*.';
	STOP THE ACTION.

[CC][LB]";
	STOP THE ACTION.
	


section 3 - searching

the standard search containers rule does nothing when searching the sack.
the examine containers rule does nothing when the sack is on the great rock.

carry out searching the sack:
	if the sack is not carried by the player:
		say "Pick it up first." instead;
	otherwise:
		say "Even though you can see its bottom, it seems bottomless[dot][pb][if something is enclosed by the sack]Circling motionless within:[lb][end if]";
		now all things enclosed by the sack are marked for listing;
		if no things enclosed by the sack are marked for listing:
			say "The sack holds only a whirpool within it.";
		otherwise:
			list the contents of the sack, with newlines, indented, including contents, giving inventory information, with extra indentation, listing marked items only.

Section 4 - delumining

Check delumining the great rock when the player is exploding:
	if the sack is not carried by the player:
		say "(first taking the sack)";
		try silently taking the sack;
		say "The sack has a rightness in the hand and over the shoulder. It was meant and made for you.";
	continue the action.
	
Carry out delumining the great rock when the player is exploding:
	say "The darkness flies from your hand, striking the rock and reducing it to blown dust. A moment's satisfaction follows, then nothing.";
	now the player is tinert.
	
Carry out delumining the sack:
	say "You pause. The sack contains a power beyond your understanding and is immune to your tricks.".

Book 14 - endless stair

Chapter 1 - rules and whatnot

Chapter 2 - description and definitions

the Endless Stair is north of Junction.
endless stair is in greater earthquake territory.
the printed name of endless stair is "Endless Stair".
the Description of the endless stair  is "[if the thief is not a time traveller]If all things end, this stair is not a thing, Ignore this certainty by failing to go *UP* or else go back (*SOUTH*).

An aphosis blocking the stair seems impermeable, even for a creature of darkness.[otherwise]This stairway leads to a recently/previously permeable darkness. The only way forward is *UP*."

Chapter 3 - nouns in the endless stair

Section 1 - the endless stairway

the endless stairway is in endless stair.
the endless stairway is scenery.
the printed name of stairway is "stairs".
understand "endless / stair / stairs / stairway" as the endless stairway.

The description of the endless stairway is "Presently impassable, not yet unfuturable. A powerful aphosis blocks the stair, and appears impermeable."

Section 2 - the permeable darkness

the impermeable darkness is in endless stair.
the impermeable darkness is scenery.
understand "dark" and "powerful / aphosis" as the impermeable darkness.


the description of the impermeable darkness is "The darkness covering the stair is obstacle, not asset.".

instead of wielding aphotic magic when the noun is impermeable darkness:
	say "The darkness on the stair is aphotic, but it is a dark too dark, a sight not seen to see.".
	
instead of doing anything other than examining or wielding aphotic magic when the current action involves the impermeable darkness:
	say "There is nothing you, a creature of darkness, can do to the impermeable darkness with hand or eye."
	
instead of delumining the endless stairway:
	try delumining the impermeable darkness.

the permeable darkness is nowhere.
the permeable darkness is scenery.
the permeable darkness is aphotic.

Chapter 4 - actions in the endless stairway

section 1 - going

instead of going up in endless stair:
	try touching the impermeable darkness instead.
	
instead of climbing the endless stair:
	try going up instead.
	
check going nowhere in endless stair:
	say "[OC]

CHECK GOING NOWHERE IN ENDLESS STAIR:
[F2]SAY 'THE JUNCTION IS TO THE *SOUTH*. AN *IMPERMEABLE DARKNESS* CURRENTLY BLOCKS THE LONG STAIR LEADING *UP*.';
[F2]STOP THE ACTION.

[CC][LB]";
	STOP THE ACTION.
	
section 2 - delumining

instead of delumining the impermeable darkness:
	try empowering the snake.
	
empowering the snake is an action applying to nothing.
empowering the snake is creating a temporal paradox.
carry out empowering the snake:
	choose row with an aphosis of the aphosis of the player in the table of aphoses;
	let the current aphosis be the pname entry;
	say "The impermeable darkness greedily devours the [current aphosis]. Energized, it rears back, a serpent-shaped hole in reality, before enveloping you in a strange absence, unmaking


[t2]***You Have Failed to Unmake the Past***[pb]

[ro]

[CAP], WHERE WOULD YOU BE WITHOUT ME? LESS THAN DEAD, LESS THAN NOWHERE, LESS THAN REMEMBERED.

[rc]

dissipates, leaving you standing at the foot of the stairs."

Book 15 - Barren Area

Chapter 1 - Description

Barren Area is west of Junction.
Barren Area is in monstrous west.

The description of the barren area is "The blank darkness of this flat, empty area is violated by a flattening, empty light. It spills in from the *WEST*, where the living things of this country might live. The safety of the underground lies to the *EAST*. Even at a distance, the sun's light thins your blood.

To the *SOUTHWEST*, you hear the deep roar of an approaching creature, followed by footsteps that shake the earth.".

Chapter 2 - Nouns

Section 1 - the barren light

The barren light is in barren area.
the barren light is scenery.
the description of the light is "This weak light is enough to weaken you."
Instead of doing anything other than wielding aphotic magic or examining to the barren light:
	say "Looking at the light, let alone approaching it, won't kill you. It wouldn't kill you [it]enough[rt], anyway.".
	
Instead of wielding aphotic magic when the current action involves the barren light:
	say "You are powerless in the presence of light.".
	
Section 2 - the sun

the barren sun is in barren area.
the barren sun is scenery.
the description of the barren sun is "You will know it by its works.".
instead of doing anything to the barren sun:
	say "The sun crouches in wait at the mouth of every cave, but you cannot go to meet it.".

Chapter 3 - Actions

[Before doing something in the btn rm when the button is depressed:
	if the current action is going somewhere:
		say "As you leave, you hear the button pop back to its orginal position.";
	otherwise:
		say "The button pops back into its orginal position.[first time]]


	
Before doing something in barren area:
	if the current action is going west:
		try being illuminated instead;
	otherwise if the current action is going northwest:
		try being illuminated instead;
	otherwise if the current action is going east:
		say "You retreat eastward.";
		now the dorn is not imminent;
	otherwise:
		now the dorn is imminent;

a monster is a kind of animal.
the dorn is a monster.
the dorn can be imminent.
the dorn is not imminent.
		
Every turn when the player is in the monstrous west and BI is false:
	if the dorn is imminent:
		try teasing the shadow dorn.
	
Teasing the shadow dorn is an action applying to nothing.
teasing the shadow dorn is creating a temporal paradox.
Carry out teasing the shadow dorn in monstrous west when BI is false:
	say "The dorn is a mythical beast said to live in the most desolate corners of the Empire. Any one of its many eyes can paralyze victims with a glance. Though stories are told of a so-called 'shadow dorn' made from primordial darkness, no one has seen one and lived. That record, it seems, will go unbroken, since the one crashing through a gap in the wall to the southwest charges straight for you, mouth


[t2]***You Have Failed to Unmake the Past***[pb]

[ro]

NOTHING[em]CERTAINLY NOT YOU[em]CAN KEEP YOU FROM YOUR FATE.

[rc]

You have been returned to the safety of the Junction.";
	now the dorn is not imminent;
	if the location is not junction:
		now the player is in Junction.
	
section 2 - going

after going west from junction:
	now BI is false;
	continue the action.

Instead of going west in barren area:
	now BI is true;
	try being illuminated;
	stop the action.
		
before going northwest in barren area:
	now BI is true;
	try being illuminated;
	stop the action.
	
check going nowhere in barren area:
	say "[OC]

CHECK GOING NOWHERE IN THE BARREN AREA:
[F2]SAY 'MISERABLE SUNLIGHT *WEST* AND *NORTHWEST*. A SHADOWY BEAST *SOUTHWEST*. SAFETY: *EAST*.';
[F2]STOP THE ACTION.

[CC][LB]".

	
BI is a truth state that varies.
	
being illuminated is an action applying to nothing.
being illuminated is creating a temporal paradox.
carry out being illuminated:
	say "You are unmade by light

[ro]

[CAP], I HOPE THAT THAT WAS INSTRUCTIVELY PAINFUL. YOU MAY NEVER AGAIN LIVE IN THE LIGHT.

I MADE YOU THAT WAY.

[RC]

safety of the junction.";
	now the dorn is not imminent;
	if the location is not junction:
		now the player is in junction;
	now BI is false.
	

	
instead of going southwest in the barren area when BI is false:
	say "You charge headlong into the path of a shadow dorn.[run paragraph on]";
		try teasing the shadow dorn;
		
instead of going nowhere in the barren area when BI is false:
	try teasing the shadow dorn.



Book 16 - Creepy Crawl

Chapter 1 - descriptions and definitions

Creepy Crawl is south of Junction.
The printed name of Creepy Crawl is "Creepy Crawl".
The creepy crawl is in greater earthquake territory.
The description of creepy crawl is "This cramped darkness would likely unnerve the living, were any within reach. It is otherwise a bland knot of exits. *NORTH* will return you to the Junction, while to the *SOUTHWEST* a gap in a stone wall leads to a shadowy[em]shadowy even here, in the dark[em]realm. The passage *EAST* looks familiar. Perhaps you were here once, many years ago.

The southern passage is hopelessly caved in, a mouth filled with stone.".

Chapter 2 - nouns

the knot is in creepy crawl.
the knot is scenery.
understand "knot / exits" as the knot.
instead of doing anything when the current action involves the knot:
	say "Much of what I do here is metaphor, but I hope I am never so on the nose."
	
the gap is in creepy crawl.
the gap is scenery.
understand "gap in wall" and "wall gap" and "wall" and "gap wall" as the gap.
the description of the gap is "Cut stone usually covers natural rock, but behind this stone wall likes an open, rolling area that seems darker than the dark somehow. There is nothing beyond sensory data and inituition to suggest that you could not go there.".
instead of doing anything other than examining or wielding aphotic magic when the current action involves the gap:
	say "There is little you can do to affect the wall. There is little it can do to affect you.".
	
the southern passage is in creepy crawl.
the southern passage is scenery.
understand "southern / passage / mouth / stone" as the southern passage.

carry out delumining the southern passage when the player is exploding:
	say "You break some large rocks with the power of darkness, but it doesn't produce the kind of cave-in one might or might not desire.

[ro]

BE MORE CAREFUL, [CAP]. THERE IS WORK TO BE DONE.

[RC][LB].";
	now the player is tinert.
	
Chapter 3 - actions

Carry out delumining the gap:
	if the player is damp:
		say "With a flick of your wrist, you manage to dampen a small portion of the stone wall.";
		now the gap is wet;
		now the player is tinert;
	otherwise if the player is exploding:
		try teasing the shadow dorn.
		
Carry out teasing the shadow dorn in creepy crawl:
	say "You concentrate on the might of the *CRASHING DARKNESS*, then use it to punch through the ancient stone wall. A long section falls with a crash. Only a few seconds of silence follow.

[oc]

CARRY OUT DELUMINING THE GAP WHEN THE THIEF IS EXPLODING:
[lb][t2][fls]TRY TEASING THE SHADOW DORN.

[cc]

The dorn is a mythical beast said to live in the most desolate corners of the Empire. Any one of its many eyes can paralyze victims with a glance. Though stories are told of a so-called 'shadow dorn' made from primordial darkness, no one has seen one and lived. That record, it seems, will go unbroken, since the one galloping across the shadowy plain charges straight for you, mouth

[ro]

NOTHING[em]CERTAINLY NOT YOU[em]CAN KEEP YOU FROM YOUR FATE.

[rc]

The darkness contracts around you, then expands outward. The wall has been restored as if nothing ever happened.";
	now the dorn is not imminent.
	
section 2 - going

instead of going south in creepy crawl:
	say "Nothing[em]alive or dead[em]will pass that way again.".
	
instead of going nowhere in creepy crawl:
	SAY "[OC]

INSTEAD OF GOING NOWHERE IN CREEPY CRAWL:
[F2]SAY 'A SHADOWY REALM LIES TO THE *WEST* AND *SOUTHWEST*. THE JUNCTION IS *NORTH OF HERE, AND A FAMILIAR-LOOKING PATH LEADS *EAST*.';
[F2]STOP THE ACTION.

[CC][LB]";
	stop the action.

	
Book 17 - Land of Shadow

land of shadow is southwest of creepy crawl.
land of shadow is in monstrous west.
the printed name of land of shadow is "Land of Shadow".

the description of land of shadow is "[shadow description]".

to say shadow description:
	say "This is the eastern expanse of dark, featureless hills. Despite the topography, this realm is entirely underground. You can return to the comforts of the creepy crawl by heading *EAST*.[run paragraph on]";
	choose row with an anomaly of teasing the shadow dorn in the table of causal anomalies;
	if turns passed entry is greater than zero:
		say " [pb]You hear the roar of a large creature approaching from the southwest.[run paragraph on]".
		
creepy crawl is east of land of shadow.

Chapter 2 - nouns

the hills are in land of shadow.
the hills are scenery.
instead of doing anything when the current action involves the hills:
	say "These many hills cover a significant amount of terrain. They evoke a mood. They may even question our received knowledge about geology. They do things, in other words, but you do not do things to them.".

Before doing anything in land of shadow:
	if the current action is going somewhere:
		say "You return to the safety of the Creepy Crawl.";
		now the player is in Creepy Crawl;
		now the dorn is not imminent;
		stop the action;
	otherwise:
		now the dorn is imminent.
		
Chapter 3 - going

before going nowhere in land of shadow:
	say "You need not go nowhere; you're already there.";
	try silently waiting instead.
	
Book 18 - crystal grotto

Chapter 1 - Descriptions and what not

crystal grotto is east of creepy crawl.
the printed name of crystal grotto is "Crystal Grotto".
the description of crystal grotto is "The dramatic shift in surroundings here quickens even your dead heart: crystal-encrusted stalactites and stalagmites jut upward and downward in this naturally-shaped room. You stand in the mouth of a jeweled serpent spread across a black cloth. Gentle, indirect lights from unseen sources dazzle and flicker.

This area seems to have avoided the earthquake damage visible elsewhere in the complex. A tight passage leads *WEST*, and a man-made opening beckons to the *SOUTH*.".


Chapter 2 - nouns

section 1 - stalactites

cave features are a kind of thing.

stalactites are in crystal grotto.
stalactites are cave features.
stalactites are scenery.
stalactites is a plural-named thing.	
the description of the stalactites is "Stone icicles gather the light.".

instead of doing anything when the current action involves the stalactites:
	say "The gentle light bent by the stalactites pevents you from approaching or even looking too closely." instead.
	
section 2 - stalagmites

stalagmites are in crystal grotto.
stalagmites are a plural-named thing.
stalagmites are scenery.
stalagmites are cave features.
the description of the stalagmites is "Stone pillars gather the light.".

section 3 - slag heap

the slag heap is nowhere.
the slag heap is scenery.
understand "stone / sludge / mud / grit / pile" as the slag heap.
the description of the slag heap is "An outside that matches your inside.".

Chapter 3 - actions

section 1 - general

Instead of doing anything other than examining when the current action involves the slag heap:
	say "[oc]

INSTEAD OF DOING ANYTHING OTHER THAN EXAMINING WHEN THE CURRENT ACTION INVOLVES THE SLAG HEAP:
[lb][t2][fls]SAY 'Leave it. Your work here is done.'.

[cc]

Leave it. Your work here is done."


instead of doing anything when the current action involves the stalactites:
	say "The gentle light bent by the stalagmities pevents you from approaching or even looking too closely."
	
Section 2 - trashing the joint
	
before delumining a cave features:
	if the player is damp:
		say "You cast the *SEEPING DARKNESS* in the direction of the [noun]. Unfortunately, the moisture in the air masks the effect.";
	if the player is exploding:
		say "As little as I think of you, it is still possible to surprise me. Using the power of the *CRASHING DARKNESS* in this small area has predictable results. The crytalline features of the grotto crack and shatter, leaving nothing but a dull heap of stone and sludge at your feet. Bravo.";
		now the stalagmites are nowhere;
		now the stalactites are nowhere;
		now the description of the crystal grotto is "This room is piled high with mud, grit, and dark. You can leave to the *EAST* or *SOUTH*.";
		now the slag heap is in crystal grotto;
		rule succeeds.


Section 3 - coming and going

before going west from crystal grotto:
	say "The passageway becomes quite crampted and you have to momentarily duck your head before reaching the next room.".
	
before going east from creepy crawl:
	say "The passageway becomes quite cramped and you have to momentarily duck your head before reaching the next room.".
	
check of going nowhere in crystal grotto:
	say "[OC]

INSTEAD OF GOING NOWHERE IN THE CRYSTAL GROTTO:
[F2]SAY 'THE WAY FORWARD IS *SOUTH*. TO TURN BACK, GO *WEST*';
[F2]STOP THE ACTION.

[CC][LB]";
	STOP THE ACTION.
	
Book 19 - Royal H

Chapter 1 - description

RoyalH is south of crystal grotto.
the printed name of royalh is "Royal Hall".
The Royalh is in greater earthquake territory.
The description of royalh is "This high, vaulted hall seems to rebuke the [if slag heap is in crystal grotto]once-beautiful [otherwise]natural beauty of the [end if]grotto to the north. The scale and craft of the carefully cut stones here are complimented by the Emperor's Royal Seal, which reaches some twenty feet toward the ceiling on the eastern wall."

Chapter 2 - nouns

Section 1 - stones

the carefully cut stones are in royalh.
the printed name of the carefully cut stones is "cut stones".
understand "carefully / cut / stones" as the carefully cut stones.
the carefully cut stones are a scenery backdrop.
The description of the carefully cut stones is "These large blocks of stone have been precisely cut and fitted.".

Instead of doing anything other than examining to the carefully cut stones:
	say "These stones have withstood constant earthquakes. There is little that you or your magic can do to them, and less still you can learn from them."

Section 2 - seal

The large seal is in royalh.
the large seal is scenery.
understand "large / emperor's / royal / seal" as the large seal.
the description of the large seal is "A familiar sight. Look upon his works, ye mighty.".

instead of doing anything other than examining or delumining to the large seal:
	say "What does that thing matter now?".
	
carry out delumining the large seal:
	if the player is damp:
		say "A portion of the seal[em]it is quite large, after all[em]is now damp.";
		now the large seal is wet;
		now the player is tinert;
	if the player is exploding:
		say "Despite the substantial power of the *CRASHING DARKNESS*, it does not mar the surface of the seal. Such is the resilience of empire. Or its symbology, at any rate.";
		now the player is tinert.
		
section 3 - going

CHECK going nowhere in royalh:
	say "[OC]

CHECK GOING NOWHERE IN THE ROYAL HALL:
[F2]SAY 'THE ENTRANCE TO THE ROYAL MUSEM IS JUST TO THE *SOUTH*. THE ONLY POSSIBILITY LIES TO THE *NORTH*.';
[F2]STOP THE ACTION.

[CC][LB]";
	STOP THE ACTION.
		
Book 20 - great door

Chapter 1 - description

The gDoor is south of the royalh.
the printed name of gdoor is "Great Door".
The gdoor is in the greater earthquake territory.
The description of gdoor is "Earthquakes have clearly taken their toll here, as a great iron door, covered in rust, lies face down on the floor, surrounded by large, fallen stones. The door once guarded the large room to the *EAST*, but now any and all may enter.[first time]

You know this place. This is the Royal Museum, where one of the crown jewels mysteriously disappeared. A rare case of vocational failure.[only]".

the carefully cut stones are in gdoor.

Chapter 2 - nouns

the fdoor is in gdoor.
the printed name of fdoor is "great rusted door".
fdoor is scenery.
understand "great / massive/ iron / rusted / door" as fdoor.
the description of fdoor is "The years have been unkind to this door, which could have once held even a dornbeast at bay.".

The carefully cut stones are in gdoor.

Chapter 3 - actions

instead of doing anything other than examining or delumining when the current action involves the fdoor:
	say "As is true of many persons, the most interesting thing about the door is what it has left behind.".

carry out delumining the fdoor when the player is exploding:
	say "The iron door clangs loudly against the floor.";
	now the player is tinert.
	
section 1 - going

check going nowhere in the gdoor:
	say "[OC]

CHECK GOING NOWHERE IN THE GREAT DOOR:
[F2]SAY 'YOU HAVE REACHED THE ROYAL MUSEUM. CELEBRATE THE REMAINS OF EMPIRE THROUGH A LARGE OPENING TO THE *EAST*. THE WAY BACK IS *NORTH*WARD.';
[F2]STOP THE ACTION.

[CC][LB]";
	STOP THE ACTION.
	
Book 21 - museum entrance

Chapter 1 - description

museum entrance is east of gdoor.
the printed name of museum entrance is "Museum Entrance".
the description of the museum entrance is "You've been here before. Thirteen years before your first death, the Royal Ring was stolen from an exhibit meant to showcase the Crown Jewels of the Empire. It happened just after the caves were excavated, and the door was never left unguarded.

After vigorous interrogation, it was determined that no guards left their posts. The door was never left unguarded, and the thief was never caught. You discovered his method, but never found him.

Thoughts of your storied career are interrupted by a large aftershock[em]the largest so far. The western wall suddenly and irrevocably gives, leaving a massive pile of stones piled inches from the toes of your boots. You must find another way out of here.".

last Report going east from the gdoor:
	now the printed name of the museum entrance is "Caved-In Entrance to the Royal Museum";
	now the description of the museum entrance is "This is the Royal Museum. Too small for one of the Emperor's vanity projects, but far too... something to be anything else. It has been tidily sacked: only walls, floors, and doors remain.[first time] You've been here twice: once in 776, and again in 948. The spare silence of 948 has endured until today, the last day that magic will work on this plane of existence.[only] The western wall is completely caved in, forever blocking the museum's sole entrance and exit.

Open doors to the *EAST* and *NORTH* lead to wealth and machinery, twin tines on the colonial fork. The entrance to the Royal Non-Sequitur lie *SOUTH* and *DOWN* a short stair.".

Chapter 2 - nouns

Section 1 - the wooden door

the miznian door is a door.
the miznian door is north of the museum entrance.
the miznian door is south of the technology museum.
the miznian door is open.
the miznian door is scenery.
the printed name of the miznian door is "exquisite colonial door".
understand "exquisite / colonial / wood / wooden / hardwood / north / door" as the miznian door.
the description of the wooden door is "[if the technology museum is sealed]The door has lost a fight with a mountain.[otherwise]Seemingly impervious to years and looters, this glossy density hails from the timber colonies of Miznia. It stands wide open.".

Section 2 - the stone door

the slab door is a door.
the slab door is east of the museum entrance.
the slab door is west of Jewel Room.
the slab door is open.
the slab door is scenery.
understand "heavy / gravity / defying / gravity-defying / stone / slab / door" as the slab door.
the printed name of slab door is "gravity-defying stone slab".
the description of slab door is "Some trick keeps this slab from bending from its hinges, weight and all. Thrown wide, open.".

Section 3 - the stairs

the short stair is in the museum entrance.
the short stair is scenery.
understand "short / stairs / stair" as the short stair.
the description of the short stair is "A short flight of long marble steps."

[understand "climb up stair" or "climb up stairs" or "climb up hort stair" or "climb short stairs" as a mistake("[stair substitution]")]

Section 4 - rockfall

the museum rockfall is scenery in museum entrance.
the printed name of the museum rockfall is "exit (retired)".
understand "rockfall / exit / rocks / rock / retired / exit" as the rockfall.
the description of the museum rockfall is "The museum's exit has called in sick today, and there's no one to pick up the slack.".

instead of examining west in museum entrance:
	try examining the museum rockfall instead.


Chapter 3 - actions

section 1 - opening and closing

instead of closing a door in the museum entrance:
	say "With the museum's only connecting geography forever blocked, the [noun] is a vestigality.".
	
section 2 - climbing

instead of climbing the short stair:
	try going down.
	
section 2 - going

instead of going west in museum entrance:
	say "These rocks have come to block the living and the dead.".
	
check going nowhere in museum entrance:
	say "[CC]

[fls]CHECK GOING NOWHERE IN THE MUSEUM ENTRANCE:
[F2] SAY 'YOU ARE IN FAMILIAR TERRITORY. THE SPACE ONCE INTENDED FOR THE ROYAL JEWELS LIES BEYOND A STONE DOOR TO THE EAST. THE ROYAL PUZZLE IS DOWN A SHORT STAIR TO THE *SOUTH*. THE FAMED GOLD MACHINE LIES *NORTH*WARD.';
[F2]STOP THE ACTION.

[CC][LB]";
	STOP THE ACTION.

Book 22 - the royal non-sequitur

section 0 - the suffocating area

the suffocating area is a region.

last report going north from the royal non-sequitur for the first time:
	say "[ro]

PERHAPS THE GULF BETWEEN US IS SO VAST THAT WE WILL FOREVER BE BAFFLED, MAZED BY OUR ACTIONS AND MOTIVES.

[rc][lb]"

Section 1 - description

The Royal Non-Sequitur is south of the museum entrance.
The Royal Non-Sequitur is down of the museum entrance.
The royal non-sequitur is in the suffocating area.
The printed name of the Royal Non-Sequitur is "Royal Non-Sequitur".
The description of the Royal Non-Sequitur is "The Royal Puzzle can be entered through a hole[em]The Royal Opening[em]in the floor.[first time]

[ro]

[fls]IT IS HARD TO IMAGINE ANYONE ENTERING ON PURPOSE, UNLESS IT WERE TO REACH THE ENDING OF A VIDEO GAME.

[RC][only]

Your only alternatives lie either *NORTH* and *UP*, or else *WEST*.".

Section 2 - nouns

The sstair is in the royal non-sequitur.
the sstair is scenery.
The printed name of the sstair is "short stair".
understand "short / stair / stairs" as the sstair.
the description of the sstair is "A short flight of long marble steps.".
instead of climbing the sstair:
	try going up.
	
Section 3 - the hole

The royal opening is in the royal non-sequitur.
the royal opening is scenery.
Understand "royal / hole /opening / puzzle" as the royal opening.
The description of the royal opening is "Dark into dark, an implication of aphotic magic. "

Section 4 - the note

the note is in the royal non-sequitur.
understand "well / well-preserved / note" as the note.
the description of the note is "Reproduced ink, black, on white paper. A bureaucrat's stationary. It reads:

'Warning:
	The Royal Puzzle is dangerous and it is possible to become trapped within its confines. Please do not enter the puzzle after hours when museum personnel are not present.
			  The Management'

[oref]

Dave Lebling and Marc Blank, Zork III. Cambridge, Infocom, 1982

[cref][lb]"


rule for writing a paragraph about the note:
	say "A well-preserved note lies near the Royal Opening.";
	now the note is mentioned.

Section 5 - the suffocating darkness

holy darkness is nowhere.
understand "gooey / suffocating / darkness" as the holy darkness.
the holy darkness is aphotic.
the printed name of holy darkness is "*SUFFOCATING DARKNESS*".
rule for writing a paragraph about the holy darkness:
	say "Dark, sticky, billowy, smothering. Sticky but never sweet. Coating, snuffing, quenching, stopping and blocking. Yours for the having, for the glomming: *SUFFOCATING DARKNESS*.";
	now the holy darkness is mentioned.
	
Section 5a - more darkness bullshit

A thing can be gloopy.
A thing is usually not gloopy.

After delumining something when the player is gooey:
	let pName be the printed name of the noun;
	now the printed name of noun is "[one of]gooey[or]sticky[or]gummed-up[or]ruined[or]suffocated[or]glommed[purely at random] [pName]";
	now the noun is gloopy;
	
After examining something gloopy:
	say "It's recently been coated in aphotic gunk."

Chapter 3 - actions

Section 1 - entering

Instead of entering the royal opening:
	try going down instead.
	
Instead of inserting something into the royal opening:
	say "The hole is voracious. You will neither fill nor fulfill it. What wonders does it hide?";
	
Carry out assaying the royal opening:
	say "A gooey, suffocating darkness drifts upward from the royal opening, rising like smoke. It can be yours if you *GATHER THE SUFFOCATING DARKNESS*.";
	now holy darkness is in royal non-sequitur;
	
Section 2 - assaying

[carry out assaying the holy darkness:
	say "Sticky, not sweet. Perfect for smothering people, chemical reactions, and many magical processes. Act now!".]
	
Section 3 - gathering

carry out gathering the holy darkness:
	say "You open your palms, pulling the darkness into yourself. Had you veins, they would jam and choke, drowning you in yourself.";
	now the player is gooey.
	
section 4 - going

Instead of entering the royal opening:
	try going down instead.
	
check going nowhere in the royal non-sequitur:
	say "[OC]

CHECK GOING NOWHERE IN THE ROYAL NON-SEQUITUR:
[F2]SAY 'THIS IS THE MIDPOINT OF A *NORTH*-*SOUTH* CORRIDOR. WHILE IT IS POSSIBLE TO ENTER THE ROYAL PUZZLE, [if the boondoggle is unvisited]I CAN'T IMAGINE YOU DOING THAT ON PURPOSE[otherwise]I'VE HAD ENOUGH OF THAT, EVEN IF YOU HAVEN'T[end if].';
[F2]STOP THE ACTION.

[CC][LB]";
	STOP THE ACTION.

Book 24 - the fiasco

the boondoggle is down from the royal non-sequitur.
the boondoggle is inside from the royal non-sequitur.
the printed name of the boondoggle is "Boondoggle".
The description of boondoggle is "The Royal Puzzle, a life-sized sliding tile contraption, is not part of your story. In fact, it is not part of many stories. A failure to participate in the category of the interesting, combined with a few visitor deaths, kept the puzzle empty, even at the height of Dimwit Flathead's reign. Although you never thought to come here in life, you have been gifted a second chance."

last report going from royal non-sequitur:
	if going down or going inside:
		try being stumped by the puzzle instead;
	continue the action.
	
Being stumped by the puzzle is an action applying to nothing.
being stumped by the puzzle is creating a temporal paradox.
Carry out being stumped by the puzzle:
	say "Sadly, the darkness is too much, even for you. [if the royal opening is assayed] Perhaps the amount rising from the Royal Opening was not enough? You have soon had your fill.[otherwise]Perhaps assaying the hole would have been a good first step. Ah, well, now you've stepped in it. Or climbed in it[dot][end if] The darkness pools around you, rising. You feel as if you are suffocating, even though you don't breathe. This darkness holds you fast. Even if it can't kill you, it will all but certainly keep you from your destiny and, more cruelly, a final death. You struggle against the clinging murk, but its grip


[t2]***You Have Failed to Unmake the Past***[pb]

[ro]

WHY WOULD YOU ENTER THE ROYAL PUZZLE, IF NOT TO DIE? ONLY I CAN GIVE YOU THAT. YOU WILL FIND NO BETTER OFFER. 

[rc]

parts, evaporating. You are in the Royal Non-Sequitur once more, shaking your head. Who can know the minds of the Implementers, the long-silent creators of this world?";
	now the player is in the royal non-sequitur.
	
Book 25 - side room

Chapter 1 - Description

The SideR is west of the royal non-sequitur.
The printed name of sider is "Side Room".
The royal non-sequitur is north of the SideR.

sider is a room.
sider is west from royal non-sequitur.
the description of the SideR is "You are in a narrow room. It was once lit by hidden, indirect magics, but their power was spent long ago. [if escape door is not busted]A small, metal door in the eastern wall reveals the sole purpose of this space, as it allowed visitors who gave up on the puzzle a means of escape. The door is one way, with no visible knob, handle, or latch[otherwise] A recently deformed door permits the flow of *SUFFOCATING DARKNESS* into the room[end if].

The only viable exit is a short stair to the *NORTH*.".



Chapter 2 - nouns

Section 1 - the side stair

The side stair is in the sideR.
the side stair is scenery.
The printed name of the sstair is "short stair".
understand "short / stair / stairs" as the side stair.
the description of the side stair is "A short flight of long marble steps.".
instead of climbing the side stair:
	try going north.
	
Section 2 - the door

the escape door is east of the SideR.
the boondoggle is east of the escape door.
the escape door is a door.
the escape door is closed.
the escape door is scenery.
understand "metal / door" as the escape door.
the printed name of the escape door is "metal door".
The description of the escape door is "[if escape door is not busted]The door is completely flush with the wall. There is handle. There is not even a seam one could pry. What is a door that can't be opened?[otherwise]The door sags crookedly from resilient hinges. It can no longer hold back the *SUFFOCATING DARKNESS* flowing into this space.".

Section 3 - dead end darkness

carry out assaying the dead end darkness:
	say "Sticky, not sweet. Perfect for smothering people, chemical reactions, and many magical processes. Act now!".


carry out gathering the dead end darkness:
	say "You open your palms, pulling the darkness into yourself. Had you veins, they would jam and choke, drowning you in yourself.";
	now the player is gooey.

dead end darkness is nowhere.
the printed name of dead end darkness is "*SUFFOCATING DARKNESS*".
understand "gooey / suffocating / darkness" as the dead end darkness.
the dead end darkness is aphotic.
rule for writing a paragraph about the dead end darkness:
	say "Dark, sticky, billowy, smothering. Sticky but never sweet. Coating, snuffing, quenching, stopping and blocking. Yours for the having, for the glomming: *SUFFOCATING DARKNESS*.";
	now the dead end darkness is mentioned.
	
carry out assaying the holy darkness:
	say "Sticky, not sweet. *GATHER THE HOLY DARKNESS* to harness its power.".

Chapter 3 - actions

Section 1 - opening and closing

Instead of opening or closing the escape door:
	say "[if escape door is busted]Even crumpled, the metal door will not swing on its hinges[otherwise]You cannot budge the door with the strength of you limbs."
	
Section 2 - delumining

Carry out delumining the escape door when the player is exploding:
	say "Rearing back, you direct the considerable force of the *CRASHING DARKNESS* at the door. It crumples, permitting a thick, gooey sort of darkness to emerge from newly-made openings. It is like standing in mud, if mud were *SUFFOCATING DARKNESS*.";
	now dead end darkness is in sideR;
	now the escape door is busted;
	now the player is tinert.
	
section 3 - going

instead of going up in sider:
	TRY GOING north instead.

check going nowhere in sider:
	say "[oc]

[FLS]CHECK GOING NOWHERE IN THE SIDE ROOM:
[F2]SAY 'THIS DEAD END CAN BE EXITED *UP* OR *NORTH*. [if the escape door is not busted]THE METAL DOOR TO THE EAST SEEMS IMPASSABLE[OTHERWISE] EVEN DAMAGED, THE METAL DOOR TO THE EAST IS IMPASSABLE[end if].';
[F2]STOP THE ACTION.

[CC][LB]";
	STOP THE ACTION.

Book 26 - the jewel room

Jewel Room is east of slab door.
The printed name of Jewel Room is "Jewel Room".
the description of jewel room is "This room is incomplete, with the eastern wall exposing the living rock in many places. This is where the Emperor wished to celebrate the bloody history of the Royal Jewels.

A small plaque is attached to a nearby wall."

Chapter 2 - the plaque

plaque is in jewel room.
plaque is scenery.
the description of plaque is "While the plaque is illegible after so many years, you can still recall it:

'The plaque explains that this room was to be the home of the Crown Jewels of the Great Underground Empire. However, following the unexplained disappearance of a priceless ring during the final stages of construction, Lord Flathead decided to place the remaining jewels in a safer location.  Interestingly enough, he distrusted museum security enough to place his prized possesion, an incredibly gaudy crown, within a locked safe in a volcano specifically hollowed out for that purpose.'

[oref]

Dave Lebling and Marc Blank, Zork III. Cambridge, Infocom, 1982

[cref][lb]"

instead of doing anything other than examining to the plaque:
	say "You are accountable to the history of this time, though the plaque is kind enough to omit your involvement.".
	
Chapter 3 - the living rock

living rock is in jewel room.
living rock is scenery.
the description of living rock is "Alive as you are, maybe more.".

instead of doing anything other than examining or delumining to the living rock:
	say "With any luck, you will die before this rock does.".
	
carry out delumining the living rock when the player is exploding:
	say "You pulverize a square foot or so of stone, but the experience leaves you empty in multiple senses.";
	now the player is tinert.
	
chapter 4 -going

CHECK going nowhere in jewel room:
	say "[oc]

[FLS]CHECK GOING NOWHERE IN JEWEL ROOM:
[F2]SAY 'THERE IS ONLY ONE WAY IN AND OUT OF THE JEWEL ROOM: FROM THE MUSEUM ENTRANCE TO THE *WEST*';
[F2]STOP THE ACTION.

[CC][LB]";
	STOP THE ACTION.


Book 27 - technology museum

Chapter 1 rules and descriptions

Section 1 Description

the printed name of the technology museum is "Technology Museum".
the description of the technology museum is "[if the big light is in technology museum]You stand at the threshold of the Royal Technology Museum, the home of a very rare piece of time travel technology. The objects on display here are say much about the resources and reach of the Empire, even if it frequently overguessed their utility.[otherwise]This is a monument to Emperial scientific achievement, with exhibits explaining the technologies used in what were once bleeding edge inventions.

The future has grown old.

A faded, illegible display once detailed the virtues of our knowledge. Now, it stands mute between two rusted heaps of metal and fasteners. One is gray, the other is black. Neither bears a trace of its creators, the schools that taught said inventors, or the colonists who bought such gadgets from Frobozzco merchants.

More proximately, a gold machine. A chaste, curved provocation. The shape of hope. It bears a seat, a button, and a dial. The rest is gold-dipped sensuality."

Chapter 2 - nouns

section 1 - the display

the display is in the technology museum.
the display is scenery.
understand "plaque / marble / brass / etched" as the display.
the description of the display is "We can only know [it]how[rt] proud of ourselves we were, not [it]why[rt].".

Instead of doing anything other than examining to the display:
	say "The display can no longer celebrate our invention and intelligence, which only seems fitting. Let it be.";
	
section 2 - the gray machine

the gray machine is in the technology museum.
the printed name of the gray machine is "Frobozz Magic Pressurizer".
the gray machine is scenery.
the gray machine can be switched on.
the gray machine is a container.
the gray machine can be opened.
understand "gray / grey / machine / frobozz / magic / pressurizer" as the gray machine.
The description of the gray machine is "This Frobozz Magic Pressurizer was likely used in the coal mines beyond the Frigid River. From there, the diamonds did what diamonds usually do.".

Instead of doing anything other than examining to the gray machine:
	say "[oc]

INSTEAD OF DOING ANYTHING OTHER THAN EXAMINING TO THE FROBOZZ MAGIC PRESSURIZER WHEN THE YEAR IS GREATER THAN 882:
[lb][t2][fls]'YOU CAN'T GET BLOOD OUT OF A STONE, BUT SOME STONES COME OF BLOOD.' IN SENTENCE CASE.

[cc]

You can't get blood out of a stone, but some stones come of blood.".

rule for printing room description details of the gray machine:
	do nothing instead.
the examine devices rule does nothing when the noun is the gray machine.

Section 3 - the spinner

The black machine is in technology museum.
the black machine is scenery.
the black machine is a device.
the printed name of black machine is "Frobozz Magic Room Spinner".
understand "black / frobozz / magic / room / spinner / machine" as the black machine.
the description of the black machine is "Perhaps it is best that magic end today.".
instead of doing anything other than examining to the black machine:
say "[oc]

INSTEAD OF DOING ANYTHING OTHER THAN EXAMINING TO THE FROBOZZ MAGIC ROOM SPINNER WHEN THE YEAR IS GREATER THAN 882:
[lb][t2][fls]'THESE ARE THE THINGS YOU DIED PROTECTING.' IN SENTENCE CASE.

[cc]

These are the things you died protecting."

rule for printing room description details of the black machine:
	do nothing instead.
the examine devices rule does nothing when the noun is the black machine.

Section 4 - the display

the display is in technology museum.
the display is scenery.
the printed name of the display is "illegible virtues of empire".
understand "display / propoganda / illegible / display / virtues / of / empire" as the display.
instead of doing anything other than examining to the display:
	say "INSTEAD OF DOING ANYTHING OTHER THAN EXAMINING TO THE ILLEGIBLE VIRTUES OF EMPIRE WHEN THE YEAR IS GREATER THAN 882:
[lb][t2][fls]SAY 'YOU BUILT PRISONS FOR THEIR CHILDREN AND CALLED THEM 'SCHOOLS.' IN SENTENCE CASE.

[cc]

We built prisons for their children and called them 'schools.'".

Section 5 - the big light

the big light is in the technology museum.
the printed name of the big light is "Big Light".
the description of the big light is "The Big Light, also known as a 'grueslayer,' was a line of cavern 'cleaning' products designed to eradicate local fauna such as grues and their kin.

With the fall of magic at hand, it hovers just above the gold machine as a resilient and change-resistent magical construct, as safety.

It's baleful light slaps the colorlessness from your cheeks."

Rule for writing a paragraph about the big light:
	say "[first time]All of these observations are academic, as a Big Light has retreated to the relative safety of the Gold Machine, which will likely be the last bit of magic to fail in this entire complex. Having deployed several in your lifetime, you know that a Big Light eradicates grue 'infestations' with minimal collateral casualties[dot][pb][only]The Big Light is an orb of near-perpetual lumination, fueled by imperial magic. This one is torn between the safety of the gold machine and its sole directive: destroying grues and their kin, gruekin. The room is bleached by its color-devouring light, and there is no way for you to safely move beyond the entryway of the Technology Museum.";
	now the big light is mentioned.
	
Section 6 - the gold machine

the gold machine is in the technology museum.
understand "frobozz / magic / temporizer / gold / machine" as the gold machine.
the gold machine is scenery.
the gold machine is an enterable container.
a seat is part of the gold machine.
the description of the gold machine is "[first time]The gold machine is of a different age, aesthetically. Artisians of the Flathead Dynasty mapped beauty along the paired axes of utility and extravagance. By contrast, the gold machine is a metal sculpture that just happens to travel through time. The one before you should not be a working model, but nobody could bear to take it apart, and you couldn't bear to check.

The thief who took the Royal Ring traveled from the future, took the ring, and then returned to the year 948. When you pursued, you found this place abandoned, falling apart, and infested with grues. The lighting worked only intermittently. The place was only good for leaving.

You did not tell the Emperor that his dominion had failed, since that would have gotten you imprisoned or jailed. Instead, you blamed some royal dilletante from the near future: a relative, perhaps.

[only]This device, a relic of a less brutal and encroaching people, reclines across the floor. It boasts a curved seat of laquered wood, a dial hand-numbered from zero to nine hundred and ninety-nine, and a blue, concave button. You've used one before. The numbers on the dial represent date years, and the button sends its occupant to the chosen year. The dial is currently set to [dial year].

Your last trip through time was 172 years into the future. That future[em]the year 948 G.U.E.[em]was twenty years ago.".

instead of inserting something into the gold machine:
	say "The only thing going in there is you.".

section 7 - the button

a blue button is part of the gold machine. the printed name of blue button is "button".
the description of the blue button is "A rounded button, made of magical blue substance."

section 8 - the dial

a blue dial is part of the gold machine. the printed name of the blue dial is "dial".
the description of the blue dial is "A dial large enough to accomodate its many settings. Hand lettered with white script, and made of the same blue material that the button is made of.

Currently, the dial is set to [dial year].".


dial year is a number that varies.
year is a number that varies.
the year is 968.
dial year is 968.

Section 9 - the black ball

the black ball is nowhere.
the description of the black ball is "This is a Big Light that has been covered with *SUFFOCATING DARKNESS*. It's now the size of your fist. So long, Big Light."

Chapter 3 - verbs

section 0 - general

irritation is a kind of value. the irritations are neutral, placid, aware, annoyed, and furious.
the big light has an irritation.
the big light is neutral

this is the escalation rule:
	if the big light is in the location:
		if the big light is furious:
			if the current action is not creating a temporal paradox:
				try stepping into the light instead;
				rule succeeds;
			otherwise:
				do nothing;
		otherwise if the big light is annoyed:
			say "Even though the Big Light fears the fall of magic, it has taken an interest in you. Perhaps your death could preserve it in some way.[lb]";
			now the big light is furious;
		otherwise if the big light is aware:
			say "You feel that it is dangerous to remain here near the Big Light for too long, and you certainly can't move any further into the room.[lb]";
			now the big light is annoyed;
		otherwise if the big light is placid:
			say "Sooner or later, you must face the Big Light.[lb]";
			now the big light is aware;
		otherwise if the big light is neutral:
			say "You will find yourself in the spotlight soon.[lb]";
			now the big light is placid;



every turn when the big light is in the technology museum and the player is in the technology museum:
	follow the escalation rule;
	say "[cc]

[FLS]EVERY TURN WHEN THE BIG LIGHT IS IN THE LOCATION:
[lb][t2][fls]FOLLOW THE ESCALATION RULE.

[cc][lb]"

the escalation rule does nothing when the current action is creating a temporal paradox.
	
assaying is fine.
examining is fine.
delumining is fine.
going is fine.

Instead of doing something other than fine when the big light is in the location:
	say "Until this room darkens, you can barely look inside, let alone act. [if the player is not tinert]Your magic[otherwise]Some magic[end if] might work.

[oc]

[fls]assaying is fine.
[lb]examining is fine.
[lb]delumining is fine.
[lb]going is fine.

[cc][lb]".



[Instead of doing something other than fine [wielding aphotic magic or examining or stepping into the light or having a sunburn or returning to darkness]when the location is the technology museum and the big light is in the technology museum:
	follow the escalation rule.]
		
instead of delumining in technology museum when the big light is in the location:
	if the noun is not the big light:
		do nothing;
	otherwise:
		continue the action;
		
Instead of assaying in technology museum when the big light is in the location:
	if the noun is the player:
		continue the action;
	otherwise if the noun is not the big light:
		do nothing;
	otherwise:
		continue the action.
		
instead of examining in technology museum when the big light is in the location:
	if the noun is not the big light:
		do nothing;
	


stepping into the light is an action applying to nothing.
stepping into the light is fine.
stepping into the light is creating a temporal paradox.
stepping into the light is fighting the clock.

carry out stepping into the light:
	now the big light is placid;
	if the paradox is already fulfilled:
		say "While the light has no face, you know it is looking at you.";
	otherwise:
		say "Like Icarus, you have disobeyed your father for the last time and must


[t2]***You Have Failed to Unmake the Past***[pb]

[ro]

PERHAPS YOU THINK THE LIGHT WILL NOT LEAVE ENOUGH BEHIND FOR ME TO REASSEMBLE? THIS IS MY GAME, [CAP]. MY WORLD. MY RULES. DO YOU REALLY BELIEVE THAT EVERYTHING PASSES? HERE? YOU SUFFER[em]AS YOU LIVED[em]FOR NOTHING.

[cc]

interest of poets and painters alike. Your thoughts of art and culture trail away as your body emerges once more from the dust. You wonder: what part of you thinks, when there is no part of you? And what do I talk to?

You will need power, as one always does, to move forward, to progress.";
		now the big light is placid;

[the rockfall]

the technology museum can be sealed. the technology museum is not sealed.

report going north from museum entrance when the player is gooey and the big light is in the location:
	say "The doorway to the south suddenly collapses, trapping you in the technology museum with the Big Light.";
	now the technology museum is sealed.

	
Section 1 - going

instead of going south in technology museum when the big light is in the location:
	if the technology museum is sealed:
		say "Nothing will ever pass that way again.";
	otherwise:
		say "You quickly duck out of the room.";
		now the big light is aware;
		continue the action.
		
instead of going south in technology museum when the big light is nowhere:
	say "Nothing will ever pass that way again.".
		
check going nowhere in technology museum:
	say "[OC]

[FLS]CHECK GOING NOWHERE IN THE TECHNOLOGY MUSEUM:
[F2]SAY '[bk]IF THE TECHNOLOGY MUSEUM IS SEALED[bk]THE ONLY ESCAPE IS TEMPORAL[bk]OTHERWISE[cb]THE ONLY ESCAPE LIES *SOUTH*WARD[bk]END IF[cb].';
[F2]STOP THE ACTION.

[CC][LB]";
	STOP THE ACTION.
	
Section 2 - assaying

carry out assaying in technology museum:
	if the noun is the player:
		continue the action;
		try silently jumping;
	otherwise if the noun is not the big light:
		try silently jumping;
	otherwise if the noun is the big light:
		say "You'll get no power before giving it.";

carry out delumining in technology museum:
	if the noun is not the big light:
		do nothing;
	otherwise if the noun is the big light:
		if the player is exploding:
			try having a sunburn instead;
		otherwise if the player is damp:
			try having a sunburn instead;
		otherwise if the player is gooey:
			try returning to darkness.
		
section 3 - having a sunburn

having a sunburn is an action applying to nothing.
having a sunburn is fine.
having a sunburn is creating a temporal paradox.
carry out having a sunburn:
	now the big light is placid;
	if the paradox is already fulfilled:
		say "While the light has no face, you know it is looking at you.";
	otherwise:
		say "With the glow of the Big Light corroding your darkling essence, you quickly cast the [magic at hand] in its direction[dot][if the player is exploding] The aphotic magic strikes whatever mass the Light has, sending it barreling against the rusted remains of a Frobozz Magic Room Spinner[otherwise] The aphotic magic falls over the construct like a wet sheet of white cotton, soon raining a sunshower of illuminated droplets. Sadly, your opponent, like you, cares nothing for beauty without utility[end if]. The Big Light flickers for a brief moment before floating in your direction. Cowering before it, you feel it in your hands


[t2]***You Have Failed to Unmake the Past***[pb]

[ro]


[CAP], IS IT COWARDICE OR INCOMPETENCE THAT PRODUCED THIS OUTCOME?

[rc]

vast nothing slowly transforms, and you are once again in the museum, looking[em]indirectly[em]at a Big Light.";
	
section 4 - returning to darkness

returning to darkness is an action applying to nothing.
returning to darkness is fine.
Carry out returning to darkness:
	say "With an arcane gesture, you direct the *SEEPING DARKNESS* toward the Big Light. Its radiance is a stone tossed into dark water. The darkness coats it, swallowing its light. After a moment, only a black, fist-sized ball remains. When you pick it up, you note that it has the texture and warmth of living flesh.";
	now the big light is nowhere;
	now the black ball is in technology museum;
	try silently taking the black ball;
	try looking;
	now the player is tinert.
	
After returning to darkness:
	say "[ro]

[CAP], THE GOLD MACHINE IS YOURS TO COMMAND, BUT ONLY THE DEMIURGE CAN SHAPE THE PAST.

[cc][lb]";
	continue the action.

[jesus]

section 5 - turning the dial

understand the command "set" as something new.

configuring it to is an action applying to one thing and one number.
understand "set [something] to [number]" as configuring it to.
understand "turn [something] to [number]" as configuring it to.

Instead of doing anything other than examining or configuring something to when the noun is the dial:
	say "[oc]

INSTEAD OF DOING ANYTHING OTHER THAN EXAMINING OR SETTING THE DIAL:
[lb][t2][fls]SAY 'THE NUMBERS ON THE DIAL REPRESENT YEARS (G.U.E.). CONFIGURING IT WITH THE COMMAND

*SET DIAL TO [bk]number[cb]*'.

[cc][vls][lb]"

before configuring the dial to:
	if the player is not in the gold machine:
		try entering the gold machine.
	
before pushing the button:
	if the player is not in the gold machine:
		try entering the gold machine.
	
instead of entering the seat:
	if the player is not in the gold machine:
		try entering the gold machine.
	
Carry out entering the gold machine:
	say "You sit in the gold machine, ready to operate its controls.".
	
the standard report entering rule does nothing when entering the gold machine.
	

check configuring the dial to a number when the number understood is less than zero:
	say "The only possibilities range from zero to nine hundred and ninety-nine.".
	
check configuring the dial to a number when the number understood is greater than 999:
	say "The only possibilities range from zero to nine hundred and ninety-nine.".
	
Carry out configuring the dial to a number:
	say "You turn the dial to [the number understood].";
	now the dial year is the number understood.

Section 7 - pushing the button

Check pushing the button:
	if year is dial year:
		say "Nothing obvious happens.".
		
the report pushing rule does nothing when pushing the red button.
		
Instead of pushing the button when dial year is less than 776:
	try being buried alive.
	
being buried alive is an action applying to nothing.
being buried alive is creating a temporal paradox.
carry out being buried alive:
	say "'You experience a brief period of disorientation. The area around you seems to be solidifying! Rock formations close in on you and before you can react you are engulfed in stone!'

[oref]

Dave Lebling and Marc Blank, Zork III. Cambridge, Infocom, 1982

[cref]


[t2]***You Have Failed to Unmake the Past***[pb]

[ro]

NO, [CAP]. EVEN HERE, I WILL FIND YOU.

[rc]

You are once again in the year [year].".

instead of pushing the button when dial year is 776:
		try missing your chance.

missing your chance is an action applying to nothing.
missing your chance is creating a temporal paradox.
carry out missing your chance:
	say "You experience a brief period of disorientation. You now see yourself, your living self, standing at the door, listening. Your living self is dressed similarly and holds a long stiletto. You open your mouth to speak! There is time to warn him, to get your wife and child out of town. Suddenly, the world wobbles like a thin sheet of metal snapped to


[t2]***You Have Failed to Unmake the Past***[pb]

[ro]

NO, [CAP]. YOU SEALED OUR FATES LONG AGO. DO NOT TRY TO CHANGE WHAT WAS.

[rc]

You are once again in the year [year]."

instead of pushing the button when the dial year is 777:
	try meeting royalty instead.
	
meeting royalty is an action applying to nothing.
meeting royalty is creating a temporal paradox.
carry out meeting royalty:
	say "'You experience a brief period of disorientation. When your vision returns, you are surrounded by a number of heavily armed guards, the dress and speech of which seem strange and unfamiliar. A commotion starts in the jewel room, and a person with a flat head, wearing a gaudy crown and a purple robe, bursts into the mueseum's entryway [bk]sic[cb].

'He speaks very loudly, nearly deafening the poor civil servant whose duty it is to see that his wishes are carried out. 'Aha! A thief! Didn't I tell you that we needed more security! But, no! You all said my idea to build the museum under two miles of mountain and surrounded by five hundred feet of steel was impractical! Now, what to do with this ... intruder? I have it! We'll build a tremendous fortress on the highest mountain peak, with one narrow ladder stretching thousands of feet to the pinnacle. There he will stay for the rest of his life!' His brow-beaten assistant hesitates. 'Don't you think, Your Lordship, that your plan is a bit, well, a bit much?' Flathead gives it a second's thought. 'No, not really.' he says, and you are led away. A few years later, your prison is finished. You are taken there, and spend the rest of your life in misery.'

[oref]

Dave Lebling and Marc Blank, Zork III. Cambridge, Infocom, 1982

[cref]


[t2]***You Have Failed to Unmake the Past***[pb]

[ro]

I WONDER WHY HE DOESN'T RECOGNIZE YOU? THEY DO SAY THAT DEATH CHANGES A MAN.

[rc]

disorienting blink, you find yourself in the year [year] again."

instead of pushing the button when the dial year is greater than 777 and dial year is less than 884:
	try getting zapped.
	
getting zapped is an action applying to nothing.
getting zapped is creating a temporal paradox.
carry out getting zapped:
	say "'You experience a brief period of disorientation. When your vision returns, you are confronted with a goodly number of particularly stupid-looking people dressed in peculiar uniform and pointing waffle-like objects in your general direction. One twists his waffle and you slump to the ground, dead.'

[oref]

Dave Lebling and Marc Blank, Zork III. Cambridge, Infocom, 1982

[cref]


[t2]***You Have Failed to Unmake the Past***[pb]

[ro]

NO, [CAP], DO NOT MISTAKE POSSIBILITY FOR OPPORTUNITY. YOUR STORY LIES ELSEWHERE.

[rc]

Blinking, you find yourself back in [year]."

instead of pushing the button when the dial year is greater than 948 and dial year is less than 968:
	try lighting up the past;
		
instead of pushing the button when the dial year is 947:
	try attaining the end;
	
instead of pushing the button when the dial year is 948:
	try arriving late to the party;

lighting up the past is an action applying to nothing.
lighting up the past is creating a temporal paradox.
carry out lighting up the past:
	let SB be 968;
	let time passed be sb minus dial year;
	say "[oc]

INSTEAD OF PUSHING THE BUTTON WHEN THE DIAL YEAR IS GREATER THAN 048 AND THE DIAL YEAR IS LESS THAN 968:
[lb][t2][fls]YOU EXPERIENCE A BRIEF PERIOD OF DISORIENTATION. IF YOUR VISION HAD RETURNED, YOU WOULD HAVE FOUND YOURSELF VERY CLOSE TO A BIG LIGHT THAT, UNFORTUNATELY, WON'T BE TRANSMOGRIFIED BY *SUFFOCATING DARKNESS* FOR ANOTHER [time passed] [if time passed is greater than 1]YEARS.[otherwise]YEAR.[end if] SHIELDING YOU


[t2]***You Have Failed to Unmake the Past***[pb]

[ro]

I SUPPOSE YOU THINK YOU'VE THOUGHT OF EVERYTHING.

[rc]

[fls]AGAIN IN YEAR 968.

[cc][lb]";
	now dial year is 968.

instead of pushing the button when the dial year is greater than 968:
	try being buried alive.
	
arriving late to the party is an action applying to nothing.
arriving late to the party is creating a temporal paradox.
carry out arriving late to the party:
	say "You experience a brief period of disorientation. Blinking your eyes, you see a young man standing in the doorway. He has the easy assuredness and healthy skin of a wealthy merchant's son. In one hand, he holds... the Royal Ring! The thief, here! You leap out of the seat, holding your stiletto warily.

He throws his burning torch to the ground, freeing a hand to draw an antique sword of elven


[t2]***You Have Failed to Unmake the Past***[pb]

[ro]

NO, NO, NO, [CAP]. YOU NEED TIME TO PREPARE. YOUR DESTINATION IS 947.

[rc]

in the seat once more, safely in [year]."
	
instead of pushing the button when dial year is 947:
	try attaining the end instead.
	
fiddling is a truth state that varies. fiddling is false.
	
instead of pushing the button when dial year is greater than 883 and dial year is less than 947:
	if fiddling is false:
		say "[OC]

[FLS]INSTEAD OF PUSHING THE BUTTON WHEN DIAL YEAR IS GREATER THAN 883 AND DIAL YEAR IS LESS THAN 947:
[F2]say '[bk]DIAL YEAR[cb] G.U.E. IS 968 G.U.E. WITHOUT EARTHQUAKES AND THE DEATH OF MAGIC. YOU MAKE YOUR WAY TO THE ENTRANCE, HOPING TO HAVE A

[RO]

[CAP], YOU CANNOT HIDE FROM ME IN SOME BACKWOODS YEAR. TEND TO YOUR DESTINY.

[RC]

[FLS]IN 968 AGAIN.';
[F2]NOW YEAR IS IS 968;
[F2]NOW DIAL YEAR IS 968.

[cc][LB]";
		now dial year is 968;
		now fiddling is true;
	otherwise if fiddling is true:
		say "[ro]

NO, [CAP]. THAT'S ENOUGH STALLING.

[RC][LB]";
	now dial year is 968.
	
attaining the end is an action applying to nothing.
carry out attaining the end:
	say "You experience a brief period of disorientation. Instead of immediately appearing in 947, you are stretched across a vast nothing. A blur of light fans by. You hear a voice.

'Get up,' you say. 'Shake it off.' 

Someone snivels nearby.

'Jesus Christ, get up.'

With a FWOOM, you are pushed forward. If dead men breathed, something could have knocked the air out of you. You hurtle like a space rock, all cold and silence.".

report attaining the end:
	end the story finally saying "[fls]YOU ARE SENT[vls]".
	
Volume 8 - the end

table of final question options (continued)
final question wording	only if victorious	topic	final response rule	final response activity
"consult the *GUIDE*"	true	"guide"	help request rule	--
"review the *FULL SCORE*"	true	"full score"	full score rule	--
"*COUNT ANOMALIES*"	true	"count anomalies"	anomaly counting rule	--

Volume 9

Book 1 Graphics

figure of zug guardians is the file "guardians 720.png".

[following is required for revised version of WC's Menus extension]

volume 10 - help

Book 1 - general stuff (not content)

understand "guide" as asking for help.
understand "gd" as asking for help.

To show toc (N - a number):
	now availability in row N of table of content availability is true;

To hide toc (N - a number):
	now availability in row N of table of content availability is false;

toc-toggling is an action out of world applying to one number.
Understand "toc [number]" as toc-toggling.

Carry out toc-toggling:
	let N be the number understood;
	if N is 0 or N > (number of rows in table of content availability):
		say "Out of range.";
	otherwise:
		if availability in row N of table of content availability is true:
			hide toc N;
			say "Row [N] of table of contents is now hidden.";
		otherwise:
			show toc N;
			say "Row [N] of table of contents is now visible.";
			
table of content availability
index	availability	note
1	true	""
2	true	""
3	true	""
4	true	""
5	true	""
6	true	""
7	true	--


	
Book 1 - the content

Part 1 - general

chapter 1 - default table

table of invisiclues
title (text)	subtable (table name)	description (text)	used (number)	bookpage (number)	localpage (number)
"A note to testers"	--		"[a note to testers]"
"Suggestions for beginning players"	--	"[suggestions for beginners]"
"On tone, failure, and narrative structure"	--	"[tone and so forth]"
"The magic system"	--	"[magic system]"
"Test commands"	--	"[test commands]"
"Gameplay hints"	table of hints	--
"General Questions (SPOILERS)"	table of faqs	--




section 1 - standalone documents treeing from default menu

to say a note to testers:
	say "Hello, tester!

Thanks for helping out with my project. As I mentioned in my note, this is not a playtest. I'm not looking for spelling corrections or unimplemented nouns. Instead, I'd like to hear your thoughts on the project's concept, the setting, voice, and mechanics. In other words, what would you recommend if I made a full game based on this idea? What is working, and what isn't?

In this menu system, I've included tips for new players, instructions for using the magic system, and hints. The magic system is a little different from [it]Repeat the Ending[rt]'s, so you may want to read about magic even if you've played my previous game.

This game riffs on classic adventure games from the 1980s (Zork I-III), but knowing those games is not important. It is important that the Demiurge (a character in the game) created such a world, and that there's a nostalgic backdrop to all of this, but no knowledge of old adventure games will help complete the game (that's my goal). Playing those old games isn't important for understanding the story and themes, either. In the same way, even though this game is related to [it]Repeat the Ending[rt], it could be played first. [it]I, Thief[rt] is written to stand on its own.

Thanks for volunteering! I'm excited to receive your feedback.

-d".

to say suggestions for beginners:
	say "Repeat the ending may have an art-house presentation at times, but mechanically, it is straightforward. In-game, all words, phrases, or commands that can be entered verbatim are capitalized and bracketed with asterisks. For instance, if you read:

*ASSAY THE CRASHING DARKNESS*

then you can enter

assay the crashing darkness

at the command prompt. You should be able to *EXAMINE* (or *X* for short) any nouns mentioned by the game. Usually, It is also possible to *ASSAY* (*AA* for short) things encountered in the world (see 'About the Magic System' for more information). *EXAMINE* applies to the physical world, while *ASSAY* deals with magic.

Most problems are solved with magic. No problems are solved by finding and using objects. Don't worry about failing or losing. It's impossible to get locked out of winning (with the possible exception of bugs). There are situations when timers are active. The game will always tell you this. Even if you run out of time, you are still able to succeed. I'd like the narrative to feel freaky, not the gameplay.

If something is mechanically hard to understand, I'd love to hear about this. I'm trying to make a friendly, accessible game that many people can enjoy. I know there are limits when it comes to parser games, but that is my goal.".

to say tone and so forth:
	say "Sometimes, the player fails to 'Unmake the Past.' This typically involves the death of the protagonist. It is never permanent, and does not prevent the player from advancing through the story. In fact, the player may decide that the Spymaster must resist his fate. This is the moral choice of the game. Resist or acquiesce? The ending of the game will change depending on whether or not the protagonist fights their destiny.

In the full version, the Demiurge's comments and tone will change during play based on the player's level of resistance. Unfortunately, there was no time to implement that feature for this test.

The requirements for different endings will not be very ambitious. I'd like players to arrive at them organically, allowing them to focus on the narrative.

Causal anomalies are actions that would destroy the past, if it weren't for the intervention of the Demiurge. You can review every thwarted anomaly you've discovered with the *CA* command.

This game also has a scoring system. It is more a tribute to classic games than it is a serious attempt at measuring performance. Still, it can be an indicator of progress. You can review it with the *FULL SCORE* (or *FS* for short) command.".

to say magic system:
	say "The protagonist, as a gruekin (and a dead one, at that), has access to the power of darkness itself. These potential and actual forces are referred to as 'aphotic magic.'. The process of using magic involves three phases:

[bt]Discovery:[rt] the magic must be found, of course. Often, this is obvious. The protagonist is sensitive to aphotic magic and can sense it automatically. In other cases, things may need to be *EXAMINE*d or *ASSAY*ed (an abbreviation for 'assay' is *AA*). You can also check your own magical power by *ASSAY*ing the main character. If you enter no noun after *ASSAY*, the game will assume that you mean the protagonist.

[bt]Acquisition:[rt] the protagonist must draw the magic into himself. This can be done in the presence of aphotic magic. Unless there are multiple sources of magic in an area, you do not need to specify the name of your target. Just enter *GATHER* (or *GT*). Gathering magic is useful for finding magic in one area, then carrying it to another.

[bt]Application:[rt] if you have magic at hand, you can use it by typing *DELUMINE [bk]something[cb]* (*DL* for short) at the command prompt. Note that if there is magic in the area, you do not need to manually *GATHER* it. The game will automatically collect whatever is nearby for use. as an example:

[fls]>dl can
[lb](first gathering the crashing darkness)
[lb]Once more, you gather the might of the *CRASHING DARKNESS* unto yourself.

The can explodes with a loud yet ineffectual pop.[vls]

Additionally, you can get rid of whatever magic you currently carry with the *DISPERSE* command."

to say test commands:
	say "For your convenience, this is a test release. This means that Inform's built-in debugging commands are available. The relevant chapter in the Inform 7 documentation is at this address: 

[bk]https://zedlopez.github.io/i7doc/WI_24.html[cb]

Here are the highlights:

*SHOWME*: display information on all nouns in the current location. Additionally, *SHOWME [bk]something[cb]* will provide additional detail on a specific thing.
[pb]*GONEAR [bk]somewhere[cb]*: immediately (attempt to) teleport to a location. Sometimes, the printed names and room names don't match, so this will be hit or miss.
[pb]*PURLOIN [bk]something[cb]*: attempt to place any item from the game world into the thief's possession. Note that sequence breaking with this and *GONEAR* may result in some weird behavior.
[pb]*ACTIONS*: take a look backstage and see what actions are invoked by your commands. Disable with *ACTIONS OFF*.
[pb]*RULES*: Even further backstage. Output is mostly nonsense outside of debugging. Disable with *RULES OFF*.

Additionally, I've added a command for granting the protagonist magic anytime. Type *AP* for a list of options, and *AP [bk]aphosis[cb]* to acquire magic. Like the other commands, some options were only written for specific locations.

Let me know if you have questions or trouble."


[table of companion
title (text)	subtable (table name)	description (text)	used (number)	bookpage (number)	localpage (number)
"A Note to New Players"	--	"[note]"
"[RDtitle]"	--	"[RDtxt]"
"[ABtitle]"	--	"[ABtxt1]"
"[ABtitle][em]New!"	--	"[ABtxt1]"
"[INtitle]"	table of INtexts	--
"[INtitle][em]New!"	table of INtexts	--
"Historical Context"	table of history	--
"Historical Context[em]New!"	table of history	--
"Contemporary Criticism"	table of CC	--
"Contemporary Criticism[em]New!"	table of CC	--
"[HWtitle]"	table of how	--
"[INH]"	table of hints	--
"Afterword(s)"	table of afterwords	--
"Afterword(s)[em]New!"	table of afterwords	--]

Part 2 - Hints

table of hints
title (text)	subtable (table name)	description (text)	used (number)	bookpage (number)	localpage (number)
"The opening"	table of introductions	--
"The hallway"	table of hallway	--
"The greater earthquake territory"	table of earthquake	--
"The museum"	table of museum	--
"The gold machine"	table of golmac	--



Book 1 - table of introductions

table of introductions
title (text)	subtable (table name)	description (text)	used (number)	bookpage (number)	localpage (number)
"What am I supposed to do in the treasury?"	table of hinting	"There's a lot to look at there."
"hint"	--	"treasures..."
"hint"	--	"clothes..."
"hint"	--	"a stiletto..."
"hint"	--	"Just as in real life, there's more to do here than there is time to do it."
"I don't think I chose the right topics when talking to the Dungeon Master."	table of hinting	"Oh? I don't think you need to worry."
"hint"	--	"The Dungeon Master takes his orders from the Demiurge, a god-like being. What could the words of a ghost do?"
"I'm stuck at a plain wooden door."	table of hinting	"In this game, you can gather information about objects with the *EXAMINE* and *ASSAY* commands."
"hint"	--	"There seems to be some magic beyond it."
"hint"	--	"Even though you can't open the door, you can still get a look."
"hint"	--	"*OPEN THE WINDOW*"
"hint"	--	"That seems pretty interesting."
"hint"	--	"*EXAMINE THE DARKNESS*"
"hint"	--	"*ASSAY THE DARKNESS*"
"hint"	--	"*DELUMINE THE DOOR*"


table of hallway
title (text)	subtable (table name)	description (text)	used (number)	bookpage (number)	localpage (number)
"I want to go *SOUTH*, but I keep getting smooshed"	table of hinting	"The protagonist doesn't have the strength to move or harm the statues on his own."
"hint"	--	"Try *LOOK*ing around."
"hint" 	--	"The hall is filled with *CRASHING DARKNESS*."
"hint"	--	"*DELUMINE* one of the statue pieces, then try going *SOUTH* again."
"hint"	--	"Well, shoot."
"hint"	--	"You have to *DELUMINE* all four pieces. Note: descriptions of the room and death change based on which pieces of statue are still present."
"I don't know what to do with the can or the other junk near the south end of the hall."	table of hinting	"The Demiurge drops hints about them, but they are useless in the demo. Even if they had a use, you could destroy some of these objects and still finish the game. That's a core design objective for this project."


table of earthquake
title (text)	subtable (table name)	description (text)	used (number)	bookpage (number)	localpage (number)
"I can't decide if I should take the *SEEPING DARKNESS* or hold on to some other kind of magic."	table of hinting	"There's no right answer. Do whatever feels right."
"I keep getting killed"	table of hinting	"By a creature?"
"hint"	--	"You cannot remain in the Shadow Dorn's territory for more than one turn. You will either be destroyed or else removed by the Demiurge."
"hint"	--	"Try going somewhere else, then see if things make more sense."
"What am I supposed to do with the stalactites and stalagmites?"	table of hinting	"They are susceptible to aphotic magic. Some more than others."
"hint"	--	"Your choice is important because you made it. The story will not be affected in any way."

Table of museum
title (text)	subtable (table name)	description (text)	used (number)	bookpage (number)	localpage (number)
"Oh, no, I'm stuck in here!"	table of hinting	"It's ok. You cannot be locked out of winning, no matter what you do (unless I've left a bug somewhere)."
"What is going on at the Royal Non-Sequitur?"	table of hinting	"It seems like kind of a deathtrap, doesn't it?"
"hint"	--	"Uh-oh. Still, there's something valuable to take from that."
"hint"	--	"There's powerful magic inside."
"hint"	--	"*ASSAY THE OPENING*"
"hint"	--	"There's no use for the *SUFFOCATING DARKNESS* here, but you can take some with you: *GATHER DARKNESS* (once you've found it)."
"How about this dead end hallway with a metal door?"	table of hinting	"You can't open the door."
"hint"	--	"If you have some *CRASHING DARKNESS*, you can deform the door sufficiently to release some *SUFFOCATING DARKNESS*."
"hint"	--	"This darkness isn't different from the kind you get from the Royal Puzzle. It doesn't matter how you get it, just that you get it."
"Is there anything to do with the Jewel Room?"	table of hinting	"Just worldbuilding and character history. The plaque explains what happened, and experimenting with the Gold Machine can reveal more information."
"I keep dying in the technology museum!"	table of hinting	"Don't worry too much about it, there's no downside (other than irritation)."
"hint"	--	"You can die in two ways."
"hint"	--	"The timer can run out, at which point the Big LIght eradicates the protagonist, a creature of darkness."
"hint"	--	"Unless you have what you need to defeat the Big Light, you can leave at any time by going *SOUTH*"
"hint"	--	"If you can't leave, see the question about defeating the Big Light."
"hint"	--	"The other way to die is to provoke it."
"hint"	--	"It exists to destroy darkness."
"hint"	--	"If you attack it with magic that cannot defeat it, the retaliation will be deadly."
"hint"	--	"Dying may or may not be a bad thing in such a case. See 'General Questions' for more information."
"OK, ok. How do I defeat the Big Light?"	table of hinting	"Only the right sort of aphotic magic can defeat the Big Light."
"hint"	--	"It isn't the *EXPLODING DARKNESS*."
"hint"	--	"It isn't the *SEEPING DARKNESS*, either."
"hint"	--	"There is another type of magic in the museum."
"hint"	--	"It is inside the Royal Non-Sequitur, which you can get at one of two ways."
"hint"	--	"See the questions about the Royal Non-Sequitur and the dead-end hallway for more information, then come back once you have some magic."
"hint"	--	"Once you have *GATHER*ed some *SUFFOCATING DARKNESS*, you can *DELUMINE THE BIG LIGHT*."


Table of golmac
title (text)	subtable (table name)	description (text)	used (number)	bookpage (number)	localpage (number)
"What do I do with the gold machine?"	table of hinting	"Have you read the fan fiction accompanying this demo?"
"hint"	--	"It explains what the gold machine is, and even suggests some years to try."
"hint"	--	"First, turn the dial to the year of your choice. The current year, in which all magic dies, is 968."
"hint"	--	"After pushing the button, you will be transported to the year on the dial."
"hint"	--	"There is only one 'correct' setting, which you learn by visiting a specific 'wrong' setting. That 'wrong' setting is mentioned when you *EXAMINE THE GOLD MACHINE*."
"hint"	--	"There are a few interesting destinations other than the ending. See 'General Questions' for more information."

[/ / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / ]


Book 2 - table of faqs

Table of faqs
title (text)	subtable (table name)	description (text)	used (number)	bookpage (number)	localpage (number)
"What's the deal with all of the earthquakes?"	table of hinting	"Today is kind of a big day, not just for you, but for everyone."
"hint"	--	"968 G.U.E. is the year in which magic dies. The universe will be entirely remade without magic."
"hint"	--	"It's suggested that most of the man-made caverns were made and sustained through magic."
"hint"	--	"That floating rock where the Dungeon Master lives is held up by magic."
"hint"	--	"Everything that you see in this opening will be completely destroyed within a day."
"hint"	--	"The Demiurge likes to cut things close, apparently."
"What's with these death messages? And why won't the Demiurge let me die?"	table of hinting	"Understanding the plan of the Demiurge is a mystery that will be explored throughout the game."
"hint"	--	"The Demiurge claims to know and control the fate of the protagonist."
"hint"	--	"But who is He to say that?"
"hint"	--	"There is a moral choice in this demo and game. Like most moral choices in real life, yet unlike many moral choices in video games, it is a decision that must be made again and again."
"hint"	--	"That choice is this: should the protagonist submit to the will of a creator/god, or should he rebel?"
"hint"	--	"My goal is to keep this from being a collectathon. I think finding half of the total available would lead to an optimal ending. I just want to see if the player is thoughtful about this over time, that's all."
"Where/when can I go in the Gold Machine?"	table of hinting	"Most of these dates are mentioned in '[it]Zork[rt]: The Legend of the Gold Machine.' They are part of Infocom's [it]Zork[rt] continuity, but you will never need to know those games to play [it]I, Thief[rt]."
"hint"	--	"Years 0-775: the Museum does not exist. Traveling here will teleport the protagonist into solid rock."
"hint"	--	"Year 776: the Museum is under construction. This is the year in which the Royal Ring was stolen."
"hint"	--	"Year 777: the year the Museum was opened to the public."	
"hint"	--	"Years 778-788: normal operation of the Museum. Guards everywhere."
"hint"	--	"789: Death of Lord Dimwit Flathead. Death of the protagonist (no change in Museum operations)."
"hint"	--	"Years 790-882: continued Museum operations. Guards stationed, etc."
"hint"	--	"Years 883-946: Empire falls in 883. Guards no longer stationed at Museum. Underground abandoned; grues return."
"hint"	--	"Year 947: the protagonist's destination."
"hint"	--	"Year 948: the year that the thief of the Royal Ring hailed from. The protagonist once traveled there from 776."
"hint"	--	"Year 949-968: a Big Light takes up residence in the technology museum. The game begins in 968, the last day of magic in the world."







[/ / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / / ]

test dk with
"z/
z/
z/
z/
z/
z/
z/
z/
1/
1/
1/
z/
z/
z/
open window/
dk stone/
dk door/
s"

test frob with
"z/
z/
z/
z/
z/
z/
z/
z/
1/
1/
1/
z/
z/
z/
open window/
dl door/
s"

test hl with
"test dk/
s/
dk head/
dk arm/
dk headless/
dk disarmed/
s"

test sl with
" test hl/
s/
s/
sw/
gather/
w/
get sack/
s/
e/
s/
s/
e/
disperse/
y/
s/
ass hole/
gather/
n/
n/
dl light"


test gt with
" test hl/
s/
s/
sw/
gather/
w/
get sack/
s/
e/
s/
s/
e/
ap gooey/
n/
dl big light"

test mz with
" test hl/
s/
s/
sw/
gather/
w/
get sack/
s/
e/
s/
s/
e/"


